이전 파일과 매수를 덮어 쓰지 않고 목록을 기반으로 파일을 이동하는 배치 파일

다음은 트릭을 수행해야합니다.

@echo off 
set Source=C:\Users\siddique.gaffar\Desktop\Artworks
set Target=C:\Users\siddique.gaffar\Desktop\Artworks Copy
set FileList=C:\Users\siddique.gaffar\Desktop\Artwork TXT File\Book1.txt
echo.
if not exist "%Source%" echo Source folder "%Source%" not found & goto Exit 
if not exist "%FileList%" echo File list "%FileList%" not found & goto Exit
if not exist "%Target%" md "%Target%" 

for /F "usebackq tokens=1-2" %%a in ("%FileList%") do call :CopyFile "%%a" %%b


:Exit
echo.
echo press the Space Bar to close this window.
pause > nul
exit /b 0

:CopyFile
:: first argument  = filename
:: second argument = number of copies

REM A little trick that will put limit on 0 if second argument is empty or not a number
set secondarg=%~2
set /a limit=secondarg

REM if limit is invalid (not strict positive), exit the function
IF %limit% LEQ 0 (
    echo Invalid number of copies
    exit /b 1
)
IF NOT EXIST "%Target%\%~1" (
    copy "%Source%\%~1" "%Target%"
    IF %limit% LEQ 1 exit /b 0
    set /a limit-=1
)

REM File already exists: search correct index for filename
set index=0
set "targetfile=%target%\%~n1"
set file_ext=%~x1

:following
set /a index+=1
Rem if file with index %index% already exists, go back to get following index
IF exist "%targetfile%(%index%).%file_ext%" goto :following

Rem we have the correct index, now we can copy
set /a limit=index+limit-1
FOR /L %%g IN (%index%,1,%limit%) DO copy "%Source%\%~1" "%targetfile%(%%g).%file_ext%"
exit /b 0

긴 파일 이름이있는 경우 또 다른 옵션 은 명령 의 출력을 분석하는 대신 루프 usebackq에서 큰 따옴표를 사용 하고 경로를 for f묶는 것입니다 type.

이 함수 :CopyFile는로 파일의 존재를 확인하고 IF EXIST카운터를 사용하여 새 파일의 파일 이름에 대한 다음 색인을 찾습니다. 경로 조작 을 사용 하여 색인으로 새 파일 이름을 생성합니다.

편집 : 텍스트 파일에서 필요한 사본 수를 읽고 그 숫자를 :CopyFile함수의 두 번째 인수로 지정할 수있는 가능성을 추가했습니다 . 숫자가 주어지지 않거나 숫자가 완전 양수가 아니면 (0보다 큼) 복사본을 만들지 않습니다.

추신 : %limit%두 번째 인수가 비어있는 경우 0으로 설정되는 "작은 트릭" set은 /a플래그로 빈 변수를 0으로 대체 하기 때문에 작동합니다. 인수 변수를 직접 사용하는 경우에는 작동하지 않습니다.

set /a limit=%~2

cmd 파서가 %~2빈 문자열로 대체 되고 플래그를 set /a limit=사용하여 잘못된 할당 이 실행 되므로 두 번째 인수가 비어 있으면 오류가 발생합니다 /a. 그러나 추가 변수를 대중 교통으로 사용하는 경우 :

set var=%~2
set /a limit=var

setcmd 인터프리터가 아닌 변수 확장을 처리 하게 할 것 입니다. 는 set것을 볼 var(경우에 변수가 비어 %2비어)를 0으로 대체한다.