포함 된 형식을 사용한 역 직렬화 JSON

보유하고있는 것에 적용 할 수있는 몇 가지 효율성이 있습니다. 주로 관리자 역할을하는 다른 클래스가 필요하지 않습니다. 추가하려는 메서드 나 추가 속성을 기존 클래스에 추가 할 수 있습니다. 좀 더 관용적 인 이름 사용 :

Public Class DataItem
    Public Property id As Integer
    Public Property key As String
    Public Property name As String = ""
    Public Property title As String
    Public Property image As ImageInfo

    Public Overrides Function ToString() As String
        Return name
    End Function
End Class

Public Class ImageInfo
    Public Property full As String
    Public Property sprite As String
    Public Property group As String
    Public Property x As Integer
    Public Property y As Integer
    Public Property w As Integer
    Public Property h As Integer
End Class

관심이 없더라도 모든 이미지 속성을 그대로 두었습니다. 그런 다음 컨테이너 클래스는 컨테이너 및 관리자 클래스의 합체가 될 수 있습니다.

Public Class LeagueManager
    Public Property type As String
    Public Property version As String
    Public Property data As Dictionary(Of String, DataItem)

    Public Sub New()

    End Sub

    ' could/should be As IEnumerable(Of String)
    Public Function GetPlayerNames() As String()

        ' enumerate Values collection of dictionary,
        '  filter out those with no name 
        '  select/pick/use the DataItem.name 
        '  put them in alpha order
        '  convert from IEnumerable to an array
        Dim names = data.Values.AsEnumerable().
                        Where(Function(j) String.IsNullOrEmpty(j.name) = False).
                        Select(Function(q) q.name).
                        OrderBy(Function(k) k).
                        ToArray()
        Return names
    End Function

    Public Function GetPlayer(name As String) As DataItem
        ' first first DataItem where the names match
        Return data.Values.
            FirstOrDefault(Function(q) String.Compare(name, q.name, StringComparison.InvariantCultureIgnoreCase) = 0)
    End Function

    Public Function GetPlayers() As DataItem()
        Return data.Values.AsEnumerable().Cast(Of DataItem).ToArray()
    End Function
End Class

1. 그것들을 결합 할 필요는 없습니다 : 옵션입니다. json 관련 클래스가 복잡할수록 내가 할 가능성이 적습니다.
2. 플레이어 이름을 가져 오는 코드가 간소화되었습니다.
3. 데이터 항목에 액세스하는 방법에는 여러 가지가 있습니다.
4. 나는 어떤 소품이 어디에서 왔는지 전혀 모른다 allytips. 하나 이상의 json에 대해 하나의 클래스를 사용하려고합니까? 그렇다면 관리자와 컨테이너를 결합하지 않을 수도 있습니다.
5. Dictionary대신 일반 이 사용됩니다 SortedDictionary. Dictionary원하는 형태 나 순서로 원하는 것을 쉽게 얻을 수 있습니다 .
6. ToString()에 재정의 DataItem디버깅에 유용합니다.

관리자와 컨테이너를 결합하면 생성자에서 역 직렬화하지 마십시오. JSON.NET이 역 직렬화를 위해 또 다른 루프를 만들 때 무한 루프에 빠질 것이라고 생각합니다. 명시 적 Load 메서드를 사용하면 다른 매개 변수 / 지역 등에 대한 데이터를 (재)로드 할 수 있습니다.

GetPlayer(string)방법을 반환 한 DataItem곳에 이름 일치 (경우를 구분). 이것은 Dictionary키 에 의존하지 않고 구현 DataItems을 숨기는 실제 이름 에 의존 하지만 Nothing항목을 제거 / 삭제할 수있는 경우 반환 될 수 있습니다.

Dim JaxData = myData.GetPlayer("jax")
If JaxData IsNot Nothing Then
    ...
End If

이것은에서 반환 된 이름을 사용하여 컬렉션을 반복하는 또 다른 방법을 제공합니다 GetPlayerNames(). Count, HasPlayer그리고 필요한 다른 속성과 메서드를 추가 할 수 있습니다 . 이미지의 경우 DataItem의 또 다른 속성입니다.

Dim jstr = ...

Dim leagueData = JsonConvert.DeserializeObject(Of LeagueManager)(jstr)

' get array of names
Dim names = leagueData.GetPlayerNames()

Dim di As DataItem
For Each s As String In names
    ' get DataItem object for player named in 's'
    di = leagueData.GetPlayer(s)
    If di IsNot Nothing Then
        Console.WriteLine("{0} aka '{1}' uses image: '{2}'", di.name,
                          di.title, di.image.sprite)
    Else
        ' very unlikely:
        Console.WriteLine("Cannot find {0}", s)
    End If

Next

결과 :

Jax
Sona
Jax 일명 'Grandmaster at Arms'사용 이미지 : 'champion1.png'Sona
일명 'Maven of the Strings'사용 이미지 : 'champion3.png'