필드 1의 각 레코드 값을 비교하여 최소 및 최대 값 AWK 찾기

여기에 당신이하고있는 것보다 훨씬 쉬운 작업 솔루션이 있습니다.

/^-?[0-9]*(\.[0-9]*)?$/$1실제로 유효한 숫자인지 확인합니다 . 그렇지 않으면 버려집니다.

sort -n | awk '$1 ~ /^-?[0-9]*(\.[0-9]*)?$/ {a[c++]=$1} END {OFS="\t"; print "min","max";print a[0],a[c-1]}'

이것을 사용하지 않으면 min과 max를 초기화해야합니다. 예를 들어 첫 번째 값으로 :

awk '$1 ~ /^-?[0-9]*(\.[0-9]*)?$/ {if (min=="") min=$1; if (max=="") max=$1; if ($1<min) min=$1; if ($1>max) max=$1} END {OFS="\t"; print "min","max";print min, max}'

읽을 수있는 버전 :

sort -n | awk '
$1 ~ /^-?[0-9]*(\.[0-9]*)?$/ {
  a[c++]=$1
}
END {
  OFS="\t"
  print "min","max"
  print a[0],a[c-1]
}'

과

awk '
  $1 ~ /^-?[0-9]*(\.[0-9]*)?$/ {
    if (min=="") min=$1
    if (max=="") max=$1
    if ($1<min) min=$1
    if ($1>max) max=$1
  }
  END {
    OFS="\t"
    print "min","max"
    print min, max
  }'

귀하의 입력에는 다음과 같은 출력이 있습니다.

min     max
0.2     0.9

편집 ( awk작동 방식 에 대한 추가 정보가 필요한 주석에 응답 ) :

Awk는 lines(이름 records)을 반복 하고 각 줄에 사용할 수있는 열 (이름 fields)이 있습니다. 각 awk반복은 한 줄을 읽고 다른 것들 사이에 NR및 NF변수를 제공 합니다. 귀하의 경우에는 첫 번째 열에 만 관심 $1이 있으므로 첫 번째 열만 사용 field합니다. 양수 및 음수 정수 또는 부동 소수점과 일치하는 정규식 인 각 recordwhere $1is matching에 /^-?[0-9]*(\.[0-9]*)?$/대해 값을 배열 a(첫 번째 버전)에 저장하거나 필요한 경우 min/ max변수를 설정합니다 (두 번째 버전에서).

다음은 조건에 대한 설명입니다 $1 ~ /^-?[0-9]*(\.[0-9]*)?$/.

• $1 ~첫 번째 필드 $1가 슬래시 사이의 정규식과 일치 하는지 확인하고 있음을 의미합니다.
• ^$1필드 의 처음부터 일치를 시작 함을 의미 합니다.
• -? 선택을 의미 minus sign
• [0-9]*임의의 자릿수 (0 포함, 일치 .1하거나 -.1일치 할 수 있음)
• ()? 존재할 수 있거나 없을 수있는 선택적 블록을 의미합니다.
• \.[0-9]*해당 옵션 블록이있는 경우 a로 시작 dot하고 0 개 이상의 숫자를 포함 해야합니다 (따라서 일치 -.하거나 .일치 할 수 있습니다! 불확실한 입력이있는 경우 정규식을 조정하십시오).
• $$1필드 의 마지막 문자까지 일치 함을 의미 합니다.

을 반복 fields하려면 다음과 같이 for 루프 from 1to NF(포함) 을 사용해야합니다 .

echo "1 2 3 4" | awk '{for (i=1; i<=NF; i++) {if (min=="") min=$(i); if (max=="") max=$(i); if ($(i)<min) min=$(i); if ($(i)>max) max=$(i)}} END {OFS="\t"; print "min","max";print min, max}'

(단순함을 위해 여기에서 입력 한 내용을 확인하지 않았습니다.)

출력되는 내용 :

min     max
1       4

입력으로 더 많은 행이있는 경우 다음 입력으로 awk첫 번째 record예를 읽은 후 처리합니다 .

1 2 3 4
5 6 7 8

출력 :

min     max
1       8

이를 방지하고 첫 번째 줄에서만 작동하려면 첫 번째 줄만 NR == 1처리 하는 조건 을 추가하거나 루프 exit뒤에 문을 추가 for하여 첫 번째 줄 이후의 입력 처리를 중지 할 수 있습니다.