XPath를 사용하여 XML에서 재귀 요소를 검색하는 방법

귀하의 요구 사항이 명확하지 않습니다. 내가 이해한다고 생각하는 작은 것부터 두 번에 걸쳐 이것을해야한다고 생각합니다. 여기 부분적인 예가 있습니다.

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:exsl="http://exslt.org/common"
extension-element-prefixes="exsl">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:key name="edge-by-in" match="child1" use="in" />
<xsl:key name="edge-by-out" match="child1" use="out" />

<xsl:template match="/parent1">
    <xsl:variable name="first-pass">
        <xsl:for-each select="child1">
            <edge id="{@id}">
                <xsl:apply-templates select="." mode="find-start"/>
                <xsl:apply-templates select="." mode="find-end"/>
            </edge>
        </xsl:for-each>
    </xsl:variable>
    <output>
        <!-- process the nodes contained in $first-pass -->
    </output>
</xsl:template>

<xsl:template match="child1" mode="find-start">
    <xsl:variable name="prev" select="key('edge-by-out', in)" />
    <xsl:choose>
        <xsl:when test="$prev">
            <xsl:apply-templates select="$prev" mode="find-start"/>
        </xsl:when>
        <xsl:otherwise>
            <start>
                <xsl:value-of select="in"/>
            </start>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

<xsl:template match="child1" mode="find-end">
    <xsl:variable name="next" select="key('edge-by-in', out)" />
    <xsl:choose>
        <xsl:when test="$next">
            <xsl:apply-templates select="$next" mode="find-end"/>
        </xsl:when>
        <xsl:otherwise>
            <end>
                <xsl:value-of select="out"/>
            </end>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

</xsl:stylesheet>

이것을 입력에 적용하면 $first-pass변수에 다음이 포함됩니다.

   <edge id="1">
      <start>Starting1</start>
      <end>end1</end>
   </edge>
   <edge id="2">
      <start>Starting1</start>
      <end>end1</end>
   </edge>
   <edge id="3">
      <start>Starting2</start>
      <end>open2</end>
   </edge>
   <edge id="4">
      <start>Starting1</start>
      <end>end1</end>
   </edge>
   <edge id="5">
      <start>Starting1</start>
      <end>end1</end>
   </edge>
   <edge id="6">
      <start>Starting2</start>
      <end>open2</end>
   </edge>
   <edge id="7">
      <start>Starting2</start>
      <end>open2</end>
   </edge>
   <edge id="8">
      <start>Starting2</start>
      <end>open2</end>
   </edge>

이제 특정이 노드를 선택하려면이 옵션을 사용할 수 있습니다 (또는없는) start또는 end.