.bat 파일을 시스템 트레이에서만 실행하려면 어떻게해야합니까?

나는 이것이 간단한 .bat파일을 통해 수행 될 수 있다고 믿지 않기 때문에 이것은 AutoHotKey에 대한 작업처럼 보입니다 .

AutoHotkey (AHK)는 사용자가 반복적 인 작업을 자동화 할 수 있도록하는 Windows 용 무료 오픈 소스 매크로 생성 및 자동화 소프트웨어입니다. 그것은 시간이 지남에 따라 본격적인 스크립팅 언어로 진화 한 키보드 단축키 (또는 핫키라고도 함)를 제공하는 것을 목표로 한 스크립팅 언어에 의해 구동됩니다.

2014 년의이 포럼 게시물에 따르면 다음 과 유사한 스크립트를 사용하여 창 가시성을 전환 할 수 있습니다.

#NoTrayIcon
#Persistent

global hBatFile

/* Setup Tray icon and add item that will handle
* double click events
*/
Menu Tray, Icon
Menu Tray, Icon, C:\windows\system32\cmd.exe
Menu Tray, Add, Show / Hide Pingu, TrayClick
Menu Tray, Add, Close Pingu, CloseItem
Menu Tray, Default, Show / Hide Pingu

;// Run program or batch file hidden
DetectHiddenWindows On
Run pingu.bat,, Hide, PID
WinWait ahk_pid %PID%
hBatFile := WinExist()
DetectHiddenWindows Off
return

TrayClick:
OnTrayClick()
return

;// Show / hide program or batch file on double click
OnTrayClick() {
    if DllCall("IsWindowVisible", "Ptr", hBatFile) {
        WinHide ahk_id %hBatFile%

    } else {
        WinShow ahk_id %hBatFile%
        WinActivate ahk_id %hBatFile%
    }
}

CloseItem() {

       DetectHiddenWindows On
       WinWait ahk_class ConsoleWindowClass
       Process, Close, cmd.exe
       DetectHiddenWindows Off
       ExitApp

}

이 스크립트는 AutoHotKey 1.1.24.00 (2016 년 5 월)에서 테스트되었습니다.

수정 : 개선 된 OP 수정 버전에 대한 링크입니다.

이 경우 :

• pingu.bat 는 실행할 배치 파일의 (임의) 이름입니다.
• hBatFile 은 일부 창 정보를 포함하는 임의의 변수 이름입니다.
• Pingu 는 추가 AHK 트레이 메뉴 항목에 표시되는 임의의 이름입니다.

스크립트를 다음과 같이 저장하고 tray.ahk( .ahk스크립트 확장에 주의 ) 두 번 클릭하여 실행하십시오 (AutoHotKey를 설치했다고 가정).

스크립트는 최소화 된 배치 파일을 시작하고 기본 AHK 스크립트 아이콘을 트레이의 소형 콘솔 창 아이콘으로 바꿉니다.

콘솔 창 가시성은 트레이 아이콘 또는 추가 된 트레이 메뉴 항목 (선택 메뉴 하단에 굵게 표시됨)을 두 번 클릭하여 토글 할 수 있습니다.

Close아래에 추가 된 메뉴 항목을 사용 하여 배치 파일과 명령 창을 모두 닫을 수 있습니다 Show / Hide( Exit콘솔 창이 아닌 스크립트 만 닫음).

또한

Run pingu.bat,, Hide, PID

분명히 pingu.bat자신의 배치 파일 이름으로 바꿔야합니다. 이 줄은 AHK 스크립트가 동일한 디렉토리에 나타나 pingu.bat거나 pingu.bat전역 적으로 액세스 할 수 있다고 가정합니다 (즉, 시스템 경로 또는 사용자 PATH 변수의 폴더에 추가됨). 그렇지 않으면 pingu.bat실행 파일의 전체 경로 로 바꾸고 싶을 것입니다 (공백을 확인하십시오!).

주의 사항

이 스크립트는 대부분 창 가시성에 대한 인터페이스 역할을합니다. 이것이 의미하는 바는 Exit트레이 아이콘 을 통해 배치 파일이 아닌 AHK 스크립트 만 종료한다는 것입니다.

간단한 해결책은 추가 된 Close메뉴 항목 을 사용 하여 스크립트를 종료하고 중지하는 것 cmd.exe입니다. 또는 다음을 수행 할 수 있습니다.

• 콘솔 창을 표시하고 Ctrl+ C(또는 빨간색 'X'로 콘솔 창을 닫음)를 사용하여 일괄 처리를 종료합니다.

• ExitAHK 스크립트를 중지하려면 트레이 아이콘에서 선택하십시오.

언급했듯이 그들은 별도의 프로세스입니다.

참고 : 숨겨진 창이있는 고아 콘솔 프로그램은 AHK 스크립트가 Exit먼저 종료 된 경우 다시 직접 액세스 할 수 없습니다. 하지만 작업 관리자를 사용하여 관련 cmd.exe프로세스 를 닫을 수 있습니다 .

Close하나가있는 경우 서면으로 메뉴 항목은 잘 작동 cmd.exe과정. 그러나 둘 이상의 cmd.exe프로세스가 실행중인 경우 스크립트로 시작한 배치 파일이 제대로 닫히지 않을 수 있습니다 (다른 항목이 닫힐 수 있음). 대신 프로세스 ID (PID)로 마감을 조사 할 수 있습니다. 즉, 위의 동일한 표시 / 닫기 / 종료 프로세스를 사용할 수도 있습니다.

스크립트 노트

Menu Tray, Icon, C:\windows\system32\cmd.exe

관련 포함 아이콘 파일이있는 컴파일 된 실행 파일의 위치를 ​​나타냅니다. 이를 포함 된 아이콘이있는 실행 파일에 대한 참조 또는 .ico아이콘 파일에 대한 직접 참조로 대체 할 수 있어야합니다.

Menu Tray, Icon, C:\Path\To\Icons\icon.ico