파일 목록을 가져오고 배치 파일을 사용하여 문자열 조작 (중복 검사) 및 조건에 대한 입력으로 파일 이름을 사용하는 방법은 무엇입니까?

배치 파일을 다시 코딩하기 위해 컴퓨터에있는 전체 환경을 설정해야했지만 얻은 것 같습니다.

주석 (로 시작하는 줄)을 읽고 rem배치 파일을 이해하고 필요한 경우 환경에 맞게 조정하십시오.

@echo off
REM FileReceiver.bat
setlocal

rem Get current date and time as local time independent on Windows region settings.
for /F "tokens=2 delims==." %%T in ('%SystemRoot%\System32\wbem\wmic.exe OS GET LocalDateTime /VALUE') do set "dt=%%T"

rem Reformat the date and time strong to wanted format.
set "YYYY=%dt:~0,4%"
set "MM=%dt:~4,2%"
set "DD=%dt:~6,2%"
set "HH=%dt:~8,2%"
set "Min=%dt:~10,2%"
set "Sec=%dt:~12,2%"
set "TimeStamp=%YYYY%-%MM%-%DD%_%HH%-%Min%-%Sec%"

rem Define name of the list file containing current date and time in name.
set "ListFile=FLIST_%TimeStamp%.lst"

rem Change directory (and drive).
cd /D "C:\VP"

rem Create the list file which is good here as the list of files changes
rem while running this batch file and therefore it is better to work with
rem a list file instead of running a FOR directly for each file in the
rem directory. The list file is not included in this list as it either does
rem not exist at all or it has wrong file extension as only *.txt files are
rem listed by command DIR. The log file EDI.log has also wrong file extension.
dir *.txt /A-D /B /ON >%ListFile%

rem It might be useful to delete the log file from a previous run.
if exist EDI.log del EDI.log

rem Process each file in the list file.
for /F "delims=" %%F in ( %ListFile% ) do call :ProcessFile "%%F"

rem Delete the list file as not needed anymore. It could be also kept.
del %ListFile%

rem Exit batch file.
endlocal
goto :EOF


:ProcessFile
rem The parameter passed from first FOR is the file name in double quotes.
set "FileName=%~1"

rem Ignore the files *_CNtable.txt and Dupfile.txt in same directory.
rem Command goto :EOF just exits here from subroutine ProcessFile.
if "%FileName%"=="AP_CNtable.txt" goto :EOF
if "%FileName%"=="SS_CNtable.txt" goto :EOF
if "%FileName%"=="Dupfile.txt" goto :EOF

rem Get 7th, 9th and 14th element from first line of current file.
for /f "usebackq tokens=7,9,14 delims=~*^" %%a in ( "%FileName%" ) do (
   set "ISAsender=%%a"
   set "ISAreceiver=%%b"
   set "ISActrlnum=%%c"
   goto WriteToLogFile
)

:WriteToLogFile
rem Remove all spaces as ISAsender and ISAreceiver have
rem usually spaces appended at end according to example
rem text. Then write file name and the 3 values to log file.
set "ISAsender=%ISAsender: =%"
set "ISAreceiver=%ISAreceiver: =%"
set "ISActrlnum=%ISActrlnum: =%"
echo %FileName%,%ISAsender%,%ISAreceiver%,%ISActrlnum%>>EDI.log

if "%ISAsender%"=="APPLESND" (
    rem Check for ISA control number in file AP_CNtable.txt.
    %SystemRoot%\System32\Findstr.exe /X /M /C:%ISActrlnum% AP_CNtable.txt >nul
    if not errorlevel 1 goto Duplicate

    echo %ISActrlnum%>>AP_CNtable.txt

    if "%ISAreceiver%"=="APPLERCV" (
        move /Y "%FileName%" "APPLE"
        echo Moved %FileName% to directory APPLE.
    )
)

if "%ISAsender%"=="SAMSUNGSND" (
    rem Check for ISA control number in file SS_CNtable.txt.
    %SystemRoot%\System32\Findstr.exe /X /M /C:%ISActrlnum% SS_CNtable.txt >nul
    if not errorlevel 1 goto Duplicate

    echo %ISActrlnum%>>SS_CNtable.txt

    if "%ISAreceiver%"=="SAMSUNGRCV" (
        move /Y "%FileName%" "SAMSUNG"
        echo Moved %FileName% to directory SAMSUNG.
    )
)
rem Exit the subroutine ProcessFile.
goto :EOF

:Duplicate
rem This ISA control number is already present in file *_CNtable.txt.
echo Duplicate control %ISActrlnum% found in file %FileName%.
echo %ISActrlnum%,%FileName%>>Dupfile.txt

rem Exit the subroutine ProcessFile.
goto :EOF

목록 파일의 이름에 현재 날짜와 시간이 있어야하는 이유는 모르겠지만 알 수없는 이유로 보관하고 싶을 수도 있습니다. 이 경우 위의 코드에서 두 줄 del %ListFile%, 즉 명령이있는 줄과 위의 주석 줄 을 삭제해야합니다 .

해당 포인트 6의 변경 사항에 따라 2014-10-07에 배치 코드를 업데이트했습니다 .