고유 암호 생성을위한 임의 시드 가져 오기

복잡성 요구 사항을 충족하는 암호를 생성하는 간단한 모듈을 작성했습니다.

Module PasswordGenerator
   Private ReadOnly _alphaChars As Char() = "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz".ToArray()
   Private ReadOnly _digitChars As Char() = "0123456789".ToArray()
   Private ReadOnly _nonAlphaNumChars As Char() = "_-.,:;!$%&/()[]=+#".ToArray()
   Private ReadOnly _allPswChars As Char() = _alphaChars.Concat(_digitChars).Concat(_nonAlphaNumChars).ToArray()

   Public Function GeneratePassword(length As Integer, minNonAlphaNum As Integer, minDigits As Integer) As String
      Return GeneratePassword(length, minNonAlphaNum, minDigits, New Random(GetSeed()))
   End Function

   Public Function GeneratePassword(length As Integer, minNonAlphaNum As Integer, minDigits As Integer, rnd As Random) As String
      Dim selectedChars As List(Of Char),
          psw As String,
          rndSelectedChar As Integer
      If length < (minNonAlphaNum + minDigits) Then Throw New ArgumentException
      selectedChars = New List(Of Char)(length)
      selectedChars.AddRange(GetRandomChars(_nonAlphaNumChars, minNonAlphaNum, rnd))
      selectedChars.AddRange(GetRandomChars(_digitChars, minDigits, rnd))
      selectedChars.AddRange(GetRandomChars(_allPswChars, (length - minNonAlphaNum - minDigits), rnd))
      psw = ""
      For i As Integer = 1 To selectedChars.Count
         rndSelectedChar = rnd.Next(0, selectedChars.Count)
         psw &= selectedChars(rndSelectedChar)
         selectedChars.RemoveAt(rndSelectedChar)
      Next
      Return psw
   End Function

   Private Function GetSeed() As Integer
      Dim guidString As String
      guidString = Guid.NewGuid().ToString("N").Substring(0, 5)
      Return Int32.Parse(guidString, Globalization.NumberStyles.HexNumber)
   End Function

   Private Function GetRandomChars(charRange As Char(), count As Integer, rnd As Random) As List(Of Char)
      Dim retVal As New List(Of Char),
          selectedPos As Integer

      If count < 1 Then Return retVal
      For i As Integer = 1 To count
         selectedPos = rnd.Next(0, charRange.Length)
         retVal.Add(charRange(selectedPos))
      Next

      Return retVal
   End Function
End Module

GetSeed()함수 없이이 코드를 사용하면 루프에서 암호를 생성하면 동일한 암호를 여러 번 얻을 수 있습니다. guid를 임의의 시드로 사용하면 NewGuid함수 가 동일한 guid를 생성하지 않도록 보장 하기 때문에 동일한 암호를 얻지 못하도록 할 수 있습니다 . GUID를 생성하는 시스템 제공 기능은 동일한 GUID를 얻지 못하도록 보장하지만 일종의 예측 가능 (또는 다른 기능보다 예측 가능-예측 불가능)이기 때문에 암호화 환경에서 임의 값을 생성하도록 만들어지지 않았습니다.

• 어떤 식 으로든 내 코드를 변경하는 것이 좋습니다.
• 내 문제를 해결하기위한 더 나은 대안이 있습니까?
• 단일 무작위 객체가 GUID를 시드로 사용하는 것보다 예측하기 어렵습니까 (동일한 암호도 얻지 못하도록 보장합니다)?