모든 열을 개별적으로 UNION보다 데이터를 재구성하는 더 효율적인 방법은 무엇입니까? (접근 제한)

이 작업을 한 번 수행하므로 할 수 있습니다. 데이터를 Excel에 넣습니다 (xls가 아닌 xlsx).

나는 이와 같은 많은 데이터를 얻고 있었기 때문에 Excel에서 데이터를 피벗 해제하기 위해이 절차를 잠시 작성했습니다. 이 함수가 수행하는 작업은 여러 통합 범위 ( alt+ d, p)를 만든 다음 오른쪽 하단의 총 합계 셀을 두 번 클릭 할 때와 동일 합니다.

"|"로 분할 할 추가 비트가 있습니다. 때로는 고유하게 ID를 지정하는 레코드 (사이트 및 날짜 ..)가 많기 때문에 새 열을 만듭니다.

실행하면 범위 (모든 데이터)를 선택하고 Enter 키를 누르라는 메시지가 표시됩니다. 해당 데이터를 피벗 테이블로 변환하고 총 보조금에 대한 "세부 정보 표시"를 수행합니다. 그런 다음 피벗 테이블 시트를 삭제하고 새롭고 정규화 된 데이터를 남깁니다.

괜찮아 보이면 다시 액세스로 가져옵니다. 이 left기능을 사용하여 Var1_1->Var1

귀하의 데이터가 주어지면 이것이 내가 얻은 결과입니다.

Row Column  Value
B2811   Var1_1  5.98
B2811   Var2_1  
B2811   Var2_2  
B2811   Var2_3  
B291    Var1_1  53
B291    Var2_1  2.2
B291    Var2_2  
B291    Var2_3  
C2814   Var1_1  453
C2814   Var2_1  1.52
C2814   Var2_2  
C2814   Var2_3  
C2816   Var1_1  45654
C2816   Var2_1  5.050551
C2816   Var2_2  4.05
C2816   Var2_3  
C2819   Var1_1  4
C2819   Var2_1  3.06141
C2819   Var2_2  6.8845
C2819   Var2_3  

.

Sub UnpivotData()
    Dim OBJECT_REQUIRED_ERROR As Integer, UNABLE_TO_SHOW_DETAIL_ERROR As Integer
    OBJECT_REQUIRED_ERROR = 424
    UNABLE_TO_SHOW_DETAIL_ERROR = 1004

    Dim sourceRange As Range, sourceSheet As Worksheet
    On Error Resume Next
    Set sourceRange = Application.InputBox("Select cell(s)", Type:=8, Title:="Select range to unpivot...")
    If Err.Number = OBJECT_REQUIRED_ERROR Then
        Exit Sub
    End If
    On Error GoTo 0
    Application.ScreenUpdating = False
    Dim fullRangeAddress As String
    fullRangeAddress = "'" & sourceRange.Worksheet.Name & "'!" & sourceRange.Address(ReferenceStyle:=xlR1C1, external:=False)

    Dim pvtchache  As PivotCache, newPivotTable As PivotTable
    Set pvtchache = sourceRange.Worksheet.Parent.PivotCaches.Create(SourceType:=xlConsolidation, SourceData:=Array(fullRangeAddress), Version:=xlPivotTableVersion14)
    Set newPivotTable = pvtchache.CreatePivotTable(TableDestination:="", DefaultVersion:=xlPivotTableVersion14)            'TableName:="PivotTable2",

    Dim pivotWorksheet As Worksheet, numberOfNewColumns As Integer, detailWorksheet As Worksheet

    Set pivotWorksheet = ActiveSheet  'the last function will make this the active worksheet as default behavior
    On Error Resume Next
    pivotWorksheet.Cells(newPivotTable.RowRange.Rows.Count + 1, newPivotTable.ColumnRange.Columns.Count + 1).ShowDetail = True    'go to the bottom right corner (grand grand total)
    If Err.Number = UNABLE_TO_SHOW_DETAIL_ERROR Then
        MsgBox "Could not find the Grand Total cell. You'll have to double click it yourself to finish."
    End If

    Set detailWorksheet = ActiveSheet
    numberOfNewColumns = Len(detailWorksheet.Range("A2")) - Len(Replace(detailWorksheet.Range("A2"), "|", ""))

    Dim i As Integer
    Do While i < numberOfNewColumns
        detailWorksheet.Columns(2).Insert
        i = i + 1
    Loop

    Dim txtToColsRange As Range
    With detailWorksheet
        Application.DisplayAlerts = False
        .Range("A1") = sourceRange.Cells(1, 1)
        Set txtToColsRange = .Range(.Range("A1"), .Range("A1").End(xlDown))
    End With
    txtToColsRange.TextToColumns DataType:=xlDelimited, _
        TextQualifier:=xlDoubleQuote, ConsecutiveDelimiter:=False, Tab:=False, _
        Semicolon:=False, Comma:=False, Space:=False, Other:=True, OtherChar:="|", _
        FieldInfo:=Array(Array(1, 1), Array(2, 1)), TrailingMinusNumbers:=True

    detailWorksheet.Cells.EntireColumn.AutoFit

    pivotWorksheet.Delete
    Application.DisplayAlerts = True
    Application.ScreenUpdating = True
End Sub