동적 목록에서 임시 테이블을 만드는 방법

다음 절차를 사용하여 원하는 작업을 수행 할 수 있습니다. 다음이 필요합니다.

1. proc을 호출하기 전에 Temp Table을 만듭니다 (임시 테이블 이름을 proc에 전달합니다). 이렇게하면 저장 프로 시저에서 생성 된 임시 테이블이 proc이 종료 / 반환되면 삭제되므로 현재 범위에서 임시 테이블을 사용할 수 있습니다.
2. 임시 테이블에 하나의 필드 만 넣으십시오. 필드가 삭제되므로 데이터 유형은 관련이 없습니다 (필드 이름을 proc에 전달 함).

[ 원하는대로 proc 이름을 변경해야하지만 다음 예제에서는 temp proc 이름이 사용됩니다. ]

CREATE PROCEDURE #Abracadabra
(
    @TempTableName SYSNAME,
    @DummyFieldName SYSNAME,
    @TestMode BIT = 0
)
AS
SET NOCOUNT ON

DECLARE @SQL NVARCHAR(MAX)

SELECT @SQL = COALESCE(@SQL + N', [',
                       N'ALTER TABLE ' + @TempTableName + N' ADD [')
               + [Title]
               + N'] VARCHAR(100)'
FROM #FieldList
ORDER BY [ID]

SET @SQL = @SQL
            + N' ; ALTER TABLE '
            + @TempTableName
            + N' DROP COLUMN ['
            + @DummyFieldName
            + N'] ; '

IF (@TestMode = 0)
BEGIN
    EXEC(@SQL)
END
ELSE
BEGIN
    PRINT @SQL
END
GO

다음 예제는 사용중인 proc을 보여줍니다. 첫 번째 실행은 실행될 SQL을 간단히 인쇄하는 테스트 모드입니다. 두 번째 실행은 SQL과 SELECT를 실행하며 EXEC는 FieldList 테이블에있는 필드임을 보여줍니다.

/*
-- HIGHLIGHT FROM "SET" THROUGH FINAL "INSERT" AND RUN ONCE
-- to setup the example

SET NOCOUNT ON;

--DROP TABLE #FieldList
CREATE TABLE #FieldList (ID INT, Title VARCHAR(50))

INSERT INTO #FieldList (ID, Title) VALUES (1, 'City')
INSERT INTO #FieldList (ID, Title) VALUES (2, 'UserSuppliedFieldName')
INSERT INTO #FieldList (ID, Title) VALUES (3, 'SomeField')
*/


IF (OBJECT_ID('tempdb.dbo.#Tmp') IS NOT NULL)
BEGIN
    DROP TABLE #Tmp
END
CREATE TABLE #Tmp (Dummy INT)

EXEC #Abracadabra
           @TempTableName = N'#Tmp',
           @DummyFieldName = N'Dummy',
           @TestMode = 1
-- look in "Messages" tab

EXEC #Abracadabra
           @TempTableName = N'#Tmp',
           @DummyFieldName = N'Dummy',
           @TestMode = 0

SELECT * FROM #Tmp

출력 @TestMode = 1:

ALTER TABLE #Tmp ADD [도시] VARCHAR (100), [UserSuppliedFieldName] VARCHAR (100), [SomeField] VARCHAR (100); ALTER TABLE #Tmp DROP COLUMN [더미];