XRechnung Visualizer 및 Saxon-HE for .NET을 사용한 자체 닫힘 DIV 태그 문제

Saxon이 XdmDestination을 사용하지 않고 Serializer를 사용하여 파일이나 스트림 또는 문자열 작성기에 직접 작성하여 직렬화를 수행하도록한다면 HTML 직렬화 규칙을 준수한다고 확신합니다. XML 및 XSLT의 맥락에서 파일에서 문자열을 읽거나 파일 API를 사용하여 파일에 문자열을 쓰는 대신 XML 파서 및 XSLT 프로세서가 입력 구문 분석 및 출력 직렬화를 가능한 한 많이 처리하도록하는 것이 좋습니다.

두 가지 변환을 연결하려는 것처럼 보이므로

  var xslt1 = xsltExecutable1.Load30();
  var xslt2 = xsltExecutable2.Load30();
  
  using (var inputStream  = File.OpenRead(Path.Combine(Directory.GetCurrentDirectory(), "xrechnung.xml")) {
    using (var resultStream = File.OpenWrite(Path.Combine(Directory.GetCurrentDirectory(), "result.html") {
      xslt1.Transform(inputStream , xslt2.AsDocumentDestination(xslt2.NewSerializer(resultStream)));
    }
  }

실행 가능한 접근 방식입니다.

물론 XSLT 3에서 두 스타일 시트를 직접 변경할 수도 있습니다.

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    exclude-result-prefixes="#all"
    version="3.0">

  <xsl:param name="step1-uri" as="xs:string">https://github.com/itplr-kosit/xrechnung-visualization/raw/master/src/xsl/ubl-invoice-xr.xsl</xsl:param>
  <xsl:param name="step2-uri" as="xs:string">https://github.com/itplr-kosit/xrechnung-visualization/raw/master/src/xsl/xrechnung-html.xsl</xsl:param>

  <xsl:output method="html" indent="yes" html-version="5"/>

  <xsl:template match="/">
      <xsl:sequence
         select="transform(map {
                   'source-node' : .,
                   'stylesheet-location' : $step1-uri
                 })?output ! transform(map { 
                               'source-node' : ., 
                               'stylesheet-location' : $step2-uri 
                             })?output"/>
  </xsl:template>
  
</xsl:stylesheet>

일반적으로 fold-left일련의 스타일 시트를 연결하는 데 사용할 수 있습니다 .

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    exclude-result-prefixes="#all"
    version="3.0">

  <xsl:param name="step1-uri" as="xs:string">https://github.com/itplr-kosit/xrechnung-visualization/raw/master/src/xsl/ubl-invoice-xr.xsl</xsl:param>
  <xsl:param name="step2-uri" as="xs:string">https://github.com/itplr-kosit/xrechnung-visualization/raw/master/src/xsl/xrechnung-html.xsl</xsl:param>

  <xsl:param name="xslt-locations" as="xs:string*" select="$step1-uri, $step2-uri"/>

  <xsl:output method="html" indent="yes" html-version="5"/>

  <xsl:template match="/">
      <xsl:sequence
         select="fold-left(
                   $xslt-locations,
                   .,
                   function($doc, $xslt-location) { 
                     transform(map { 'source-node' : $doc, 'stylesheet-location' : $xslt-location })?output
                   }
                )"/>
  </xsl:template>
  
</xsl:stylesheet>