다양한 유형 및 해당 기본 클래스에 대한 오버로드

하자 내가 추상의 base class 있다고 가정 Shape_t파생 유형 Rectangle_t과 Circle_t. get_area두 파생 형식에 대한 일반 함수 가 있으며 클래스에 대해서도 오버로드하여 다음 인터페이스 (Julianesque 표기법)를 얻습니다.

get_area(type(Circle_t) :: C)
get_area(type(Rectangle_t) :: R)
! The following leads to ambiguous interfaces
get_area(class(Shape_t) :: S)

안타깝게도이 작업을 시도하면 "모호한 인터페이스"오류가 발생합니다. 이것으로부터 세 가지 질문이 있습니다.

1. 내가 달성하고자하는 것에 개념적으로 잘못된 것이 있습니까? 변수는 명시 적으로 다형성 ( class(...)) 으로 선언되기 때문에 컴파일러는 항상 가장 구체적인 인터페이스를 선택하고 다형성 인터페이스로 폴백 할 수 있습니다. 그래서 나는 모호함을 보지 못했습니다.

2. 질문 1에 대한 답이 "개념 상 모호성이 없습니다"인 경우. 이를 변경할 계획이 있습니까?

3. dyn_get_areafor dynamic polymorphism이 도입 된 다음 코드 가 확실한 해결 방법입니까? 컴파일 타임에 구체적인 Shape를 알고있는 한 가능한 한 오랫동안 정적 다형성을 고수하고 싶습니다.

module shapes_mod
    implicit none
    private
    public :: Shape_t, Rectangle_t, Circle_t, PI, get_area, dyn_get_area

    real, parameter :: PI = atan(1.0) * 4.0

    type, abstract :: Shape_t
    end type

    type, extends(Shape_t) :: Circle_t
        real :: r = 0.0
    end type

    type, extends(Shape_t) :: Rectangle_t
        real :: a = 0.0, b = 0.0
    end type

    interface get_area
        module procedure get_area_Rectangle_t, get_area_Circle_t
    end interface

    contains

    pure function get_area_Circle_t(C) result(res)
        type(Circle_t), intent(in) :: C
        real :: res
        res = C%r**2 * PI
    end function

    pure function get_area_Rectangle_t(R) result(res)
        type(Rectangle_t), intent(in) :: R
        real :: res
        res = R%a * R%b
    end function

    pure function dyn_get_area(S) result(res)
        class(Shape_t), intent(in) :: S
        real :: res
        select type(S)
        type is(Rectangle_t)
            res = get_area(S)
        type is(Circle_t)
            res = get_area(S)
        end select
    end function

end module


program test_polymorphic_and_static_overload
    use shapes_mod, only: Shape_t, Rectangle_t, Circle_t, get_area, dyn_get_area
    implicit none
    class(Shape_t), allocatable :: random_shape
    type(Circle_t) :: circle
    type(Rectangle_t) :: rectangle
    real :: p

    circle = Circle_t(1.0)
    rectangle = Rectangle_t(1.0, 2.0)

    call random_number(p)
    if (p < 0.5) then
        random_shape = circle
    else
        random_shape = rectangle
    end if

    write(*, *) get_area(circle)
    write(*, *) get_area(rectangle)
    write(*, *) dyn_get_area(random_shape)
end program