연도 번호를 나타내는 x 값이 1에서 18까지 가도록 구성된 데이터 세트가 있지만 데이터 세트에는 각 인스턴스에 대해 서로 다른 y 값으로 1에서 18까지가는 연도의 500 개 이상의 인스턴스가 포함되어 있습니다.
x_values y_values
1 0.10
2 0.20
3 0.25
. .
. .
. .
18 16.7
1 0.13
2 0.18
3 0.22
. .
. .
. .
18 17.1
이 패턴은 500 번 이상 반복됩니다.
기울기 함수를 사용하여 각 인스턴스의 기울기를 계산하고 싶습니다.
이전 시나리오에서는 각 인스턴스의 평균 y- 값을 찾고 싶었고 다음 공식을 사용했습니다.
=AVERAGE(OFFSET($B$2,(ROW()-ROW($C$2))*18,,18,))
$ B $ 2는 첫 번째 인스턴스의 첫 번째 y 값을 나타내는 참조 셀이었습니다.
비슷한 공식을 적용하여 기울기를 계산하고 싶지만 지금까지이 공식을 사용할 때 # N / A 오류가 발생합니다.
=SLOPE(OFFSET($B$2,(ROW()-ROW($D$2))*18,,18,),$A$2:$A$19)
여기서 $ A $ 2 : $ A $ 19 범위는 18 개의 x- 값을 나타냅니다.
이 오류가 발생한 이유와 해결 방법에 대한 도움을 주시면 감사하겠습니다.
수식 평가를 사용하여이 수식을 단계별로 실행하면 행 번호에 중괄호가있는 것을 볼 수 있습니다. 따라서 행 함수는 단일 요소 배열을 제공합니다. Index를 사용하여 스칼라로 만들 수 있습니다.
=SLOPE(OFFSET($B$2,INDEX((ROW()-ROW($D$2))*18,1),0,18,1),$A$2:$A$19)
참고 1 :
인덱스를 사용하고 오프셋과 같은 휘발성 함수를 사용하지 않는 것이 좋습니다.
=SLOPE(INDEX(B:B,(ROW()-ROW($B$2))*18+2):INDEX(B:B,(ROW()-ROW($B$2))*18+19),$A$2:$A$19)
노트 2:
Slope에서이 동작을 얻는 이유를 완전히 설명 할 수는 없지만 Average는 괜찮습니다. Average는 다음과 같은 배열 배열을 처리 할 수있는 것 같습니다.
=SUMPRODUCT(AVERAGE(OFFSET(A2,{1,2},0,1,1)))
Slope는 할 수 없지만 공식을 단계별로 살펴볼 때 보는 내용을 완전히 설명하지는 않습니다.
이 기사는 인터넷에서 수집됩니다. 재 인쇄 할 때 출처를 알려주십시오.
침해가 발생한 경우 연락 주시기 바랍니다[email protected] 삭제
몇 마디 만하겠습니다