Roku SG アプリケーションにディープリンクを実装するには?

あなたは正しい軌道に乗っています。ディープ リンクの目的は、ユーザーを Roku Search のリストまたはバナーからチャンネルのシーズンやエピソードに直接誘導することです。

シーン グラフ チャネル用にこれをプログラムする方法については、ドキュメントに優れた例がありません。したがって、これも自分で作成する必要がありました。実装したら、次の 2 つの方法でテストします。

1. Eclipse プラグイン -> ファイル > エクスポート > BrightScript デプロイメントを使用します。次のように DeepLinking params フィールドに入力します: contentID=1234&MediaType=episode

2. Roku Deep Link Tester を使用します: http://devtools.web.roku.com/DeepLinkingTester/

3. いくつかのディープリンク パラメータをチャネルにハードコーディングします。

main.brs にディープリンク ロジックを実装する方法は次のとおりです。

sub Main(args as Dynamic)

    screen = createObject("roSGScreen")
    m.port = createObject("roMessagePort")
    screen.setMessagePort(m.port)
    m.global = screen.getGlobalNode()

    'Deep Linking
    'args.ContentId = "78891" 'Testing only
    'args.MediaType = "episode" 'Testing only
    if (args.ContentId <> invalid) and (args.MediaType <> invalid)
        m.global.addField("DeepContentId", "string", true)
        m.global.addField("DeepMediaType", "string", true)

        m.global.DeepContentId = args.ContentId
        m.global.DeepMediaType = args.MediaType
    end if

    scene = screen.createScene("HomeScene")
    screen.show()

    '...load content, other startup logic

    while true
        msg = wait(0, m.port)
        msgType = type(msg)

        if msgType = "roSGScreenEvent"
            if msg.isScreenClosed() then exit while
        end if
    end while

    if screen <> invalid then
        screen.close()
        screen = invalid
    end if
end sub

次に、コンテンツが初期化されたら、HomeScene.brs のホーム画面で:

'Check for deep link content
if m.global.DeepContentId <> invalid then

    if (m.global.DeepMediaType = "short form" or m.global.DeepMediaType = "movie" or m.global.DeepMediaType = "episode") then
        'find selected content in feed

        'play episode or movie content directly

    else if (m.global.DeepMediaType = "season")
        'find selected content in feed
        'show season screen for content
    else
        ? "Unrecognized Deep Link Media Type"
    end if
    'It may be necessary to remove deep link params
    m.global.DeepContentId = invalid
    m.global.DeepMediaType = invalid
end if

これが Deep Linking を起動して実行するのに役立つことを願っています。何か見逃した場合はお知らせください。