＆lt;の交換方法で<ColdFusionで

debugcn 投稿 Dev

サムアレン

私はColdFusionを使用してデータベースエントリからXMLドキュメントを作成して<おり、XMLが作成されると、および>はとの形式に<なり>ます。したがって、XMLを作成する前<に、を<？に変更する方法はありますか？

以下は、コードと出力の例です。

<cfquery name="messages" datasource="showcase_Uk">
     select * from t_items where pid = 2 and spid = 45
</cfquery>

<cfset myStruct = StructNew() />
<cfset mystruct.link = "http://showcase.com" />
<cfset myStruct.title = "Examples" />
<cfset mystruct.description = "Examples from UK Showcase" />
<cfset mystruct.pubDate = Now() />
<cfset mystruct.version = "rss_2.0" />
<cfset myStruct.item = ArrayNew(1) />

<cfloop query="messages">
   <cfset myStruct.item[currentRow] = StructNew()>
   <cfset myStruct.item[currentRow].guid = structNew()>
   <cfset myStruct.item[currentRow].guid.isPermaLink="YES">
   <cfset myStruct.item[currentRow].guid.value = xmlFormat(#messages.id#)>
   <cfset myStruct.item[currentRow].pubDate = createDate(year(#messages.uploadDate#), month(#messages.uploadDate#), day(#messages.uploadDate#))>
   <cfset myStruct.item[currentRow].title = xmlFormat(#messages.name#)>
   <cfset myStruct.item[currentRow].description = StructNew() />
   <cfset myStruct.item[currentRow].description.value = xmlFormat(#messages.description#)>
</cfloop>


<cffeed action="create" name="#myStruct#" overwrite="true" xmlVar="myXML">

<cffile action="write" file="e:\domains\showcase.com\wwwroot\ukshowcasefeed.xml" nameconflict="overwrite" output="#XMLFormat(myXML)#">

 <cffile action="read" file="e:\domains\showcase.com\wwwroot\ukshowcasefeed.xml" variable="myfile">

 <cfoutput>#myfile#</cfoutput>

次に、生成されるコードのスクリーンショットを次に示します。

私は試しましたがReplaceNoCase、それはまったく変わりません。正規表現と関係があるのではないかと思いますが、よくわかりません。

トマラク

簡単な答え：

あなたXmlFormat()がファイルを書くとき、そうしないでください、それはあなたが見る二重エンコーディングを引き起こすものです。

長い答え：

マッピングを使用してフィードを作成することをお勧めします。

<cfquery name="messages" datasource="showcase_Uk">
  select
    id, uploadDate, name, description, 'yes' as isPermaLink
  from
    t_items
  where
    pid = 2 and spid = 45
</cfquery>

<cfset feedMeta = {
  version: "rss_2.0",
  title: "Examples",
  link: "http://showcase.com",
  publisheddate: Now(),
  description: "Examples from UK Showcase"
}>

<cfset feedMap = {
  title: "name",
  content: "description",
  publisheddate: "uploadDate",
  id: "id",
  idpermalink: "isPermaLink"
}>

<cffeed
  action="create"
  properties="#feedMeta#" columnMap="#feedMap#" query="#messages#"
  xmlvar="feedXml"
>

<cffile
  action="write"
  file="#ExpandPath('/ukshowcasefeed.xml')#" nameconflict="overwrite" charset="utf-8"
  output="#feedXml#"
>

フィード作成への簡単な宣言型アプローチに注意してください。ループや手動の構造体作成はなく、入力から出力へのデータ駆動型マッピングのみです。

また、エンコーディングの問題に遭遇したくない場合charset="utf-8"は<cffile>、これが不可欠であることに注意してください。

すぐに正しい列名を持つようにクエリを変更する場合は、次のfeedMap構造も必要ありません。

<cfquery name="messages" datasource="showcase_Uk">
  select
    id, 
    'yes' as idpermalink
    uploadDate as publisheddate,
    name as title,
    description as content 
  from
    t_items
  where
    pid = 2 and spid = 45
</cfquery>

<cffeed
  action="create"
  properties="#feedMeta#" query="#messages#"
  xmlvar="feedXml"
>