DelphiISAPIマルチスレッドログオブジェクトが正しく破棄されない

debugcn 投稿 Dev

user14889477

ここで説明するマルチトレッドログソリューションを使用しようとしました：Delphiマルチスレッドファイルの書き込み：I / Oエラー32。

TThreadFileLog上記のリンクで説明されているクラスをテストするために、空のDelphiISAPIプロジェクトを作成しました。

インスタンス化logされたオブジェクトがfinalizeセクションに配置されると（IISアプリプールをリサイクルする）、ISAPI DLLが正しく解放されず、IIS全体を再起動する必要があります。

誰かがlogオブジェクトを正しく解放する方法を私に提案するかもしれませんか？（私は機械エンジニアなので、プログラミングの原則が不足している可能性があります）。

unit LogUnit;

interface

uses Winapi.Windows, System.Classes, System.SysUtils, ThreadFileLog;

type
    PLogRequest = ^TLogRequest;
    TLogRequest = record
        LogText: String;
    end;

    TThreadFileLog = class(TObject)
    private
        FFileName: String;
        FThreadPool: TThreadPool;
        procedure HandleLogRequest(Data: Pointer; AThread: TThread);
    public
        constructor Create(const FileName: string);
        destructor Destroy; override;
        procedure Log(const LogText: string);
    end;

var log: TThreadFileLog;

implementation

{ TThreadFileLog }

constructor TThreadFileLog.Create(const FileName: string);
begin
    FFileName := FileName;
    FThreadPool := TThreadPool.Create(HandleLogRequest, 1);
end;

destructor TThreadFileLog.Destroy;
begin
    FThreadPool.Free;
    inherited;
end;

procedure TThreadFileLog.HandleLogRequest(Data: Pointer; AThread: TThread);
var
    Request: PLogRequest;
    F: TextFile;
begin
    Request := Data;
    try
        AssignFile(F, FFileName);
        if not FileExists(FFileName) then
            Rewrite(F)
        else
            Append(F);
        try
            Writeln(F, DateTimeToStr(Now) + ': ' + Request^.LogText);
        finally
            CloseFile(F);
        end;
    finally
        Dispose(Request);
    end;
end;

procedure TThreadFileLog.Log(const LogText: string);
var
    Request: PLogRequest;
begin
    New(Request);
    Request^.LogText := LogText;
    FThreadPool.Add(Request);
end;

initialization
    OutputDebugString('I N I T');
    log := TThreadFileLog.Create('C:\Temp\Test.log'); // <-- OK

finalization
    log.Free;                   // *** some IIS problem here when app-pool is recycled (need to restart the whole IIS)
    OutputDebugString('E N D'); // *** and this is never reached

end.

unit LogIsapiWebModuleUnit;

interface

uses System.SysUtils, System.Classes, Web.HTTPApp, Winapi.Windows;

type
    TWebModule1 = class(TWebModule)
        procedure WebModule1DefaultHandlerAction(Sender: TObject; Request: TWebRequest; Response: TWebResponse; var Handled: Boolean);
    private
        { Private declarations }
    public
        { Public declarations }
    end;

var
    WebModuleClass: TComponentClass = TWebModule1;

implementation

{$R *.dfm}

uses LogUnit;

procedure TWebModule1.WebModule1DefaultHandlerAction(Sender: TObject; Request: TWebRequest; Response: TWebResponse; var Handled: Boolean);
begin
    log.Log('WEBMODULE1 DefaultHandlerAction');
    Response.Content :=
        '<html>' +
        '<head><title>Web Server Application</title></head>' +
        '<body>Web Server Application</body>' +
        '</html>';
end;

Stijn Sandersの貴重な手がかりのおかげで、私は追加の検索を行い、おそらく次のような問題を解決する方法を見つけました。

library TestIsapiProject;

uses
    Winapi.Windows,
    Winapi.ActiveX,
    System.Win.ComObj,
    Web.WebBroker,
    Web.Win.ISAPIApp,
    Web.Win.ISAPIThreadPool,
    LogUnit in 'LogUnit.pas',
    TestIsapiMainWebModuleUnit in 'TestIsapiMainWebModuleUnit.pas' {WebModule1: TWebModule};

function TerminateExtension(dwFlags: dword): bool; stdcall;
begin
    // as per Microsoft "TerminateExtension provides a place to
    // put code that cleans up threads or de-allocate resources

    OutputDebugString('TerminateExtension BEGIN');
    log.Free;
    OutputDebugString('TerminateExtension END');

    Result := Web.Win.ISAPIThreadPool.TerminateExtension(dwFlags);
end;

exports
    GetExtensionVersion,
    HttpExtensionProc,
    TerminateExtension;

begin
    CoInitFlags := COINIT_MULTITHREADED;
    Application.Initialize;
    Application.WebModuleClass := WebModuleClass;
    Application.Run;
end.

また、問題を正確に説明し、この他の解決策を提案するこの記事を見つけました。しかし、私が確認できる限り、DoTerminateは呼び出されないようです。

library TestIsapiProject;

uses
    Winapi.Windows,
    Winapi.ActiveX,
    System.Win.ComObj,
    Web.WebBroker,
    Web.Win.ISAPIApp,
    Web.Win.ISAPIThreadPool,
    LogUnit in 'LogUnit.pas',
    TestIsapiMainWebModuleUnit in 'TestIsapiMainWebModuleUnit.pas' {WebModule1: TWebModule};

procedure DoTerminate;
begin
    // free global objects and wait/terminate threads here
  
    OutputDebugString('TerminateExtension BEGIN');
    log.Free;
    OutputDebugString('TerminateExtension END');
end;

exports
    GetExtensionVersion,
    HttpExtensionProc,
    TerminateExtension;

begin
    CoInitFlags := COINIT_MULTITHREADED;
    Application.Initialize;
    Application.WebModuleClass := WebModuleClass;
    TISAPIApplication(Application).OnTerminate := DoTerminate; // added
    Application.Run;
end.

ありがとう。

Stijn Sanders

ISAPI DLLは関数TerminateExtensionをエクスポートしますか？そこからすべてのクリーンアップコードを呼び出し、finalizationセクションに依存せずに作業を行うことをお勧めします。

この記事はインターネットから収集されたものであり、転載の際にはソースを示してください。

侵害の場合は、連絡してください[email protected]