Terraform：リクエストされたインスタンスタイプがサポートされているゾーンでのみAWS EC2インスタンスをリクエストするにはどうすればよいですか？

コメントで述べたように、優先タイプが利用できない場合に別のタイプのインスタンスを起動できれば、aws_ec2_instance_type_offeringデータソースを使用t2して、影響を受けるアベイラビリティーゾーンのインスタンスファミリーにフォールバックできます。

許可されるインスタンスタイプに次のテラフォームのコードが出力さアベイラビリティゾーンのマップを、好むt3.microが、バックに落ちるt2.microのt3家族は使用できません。

provider "aws" {
  region = "us-east-1"
}

data "aws_availability_zones" "all" {}

data "aws_ec2_instance_type_offering" "example" {
  for_each = toset(data.aws_availability_zones.all.names)

  filter {
    name   = "instance-type"
    values = ["t2.micro", "t3.micro"]
  }

  filter {
    name   = "location"
    values = [each.value]
  }

  location_type = "availability-zone"

  preferred_instance_types = ["t3.micro", "t2.micro"]
}

output "foo" {
  value = { for az, details in data.aws_ec2_instance_type_offering.example : az => details.instance_type }
}

この出力：

foo = {
  "us-east-1a" = "t3.micro"
  "us-east-1b" = "t3.micro"
  "us-east-1c" = "t3.micro"
  "us-east-1d" = "t3.micro"
  "us-east-1e" = "t2.micro"
  "us-east-1f" = "t3.micro"
}

これを出力するだけでなく、アベイラビリティーゾーンを反復処理して、aws_instanceリソースのインスタンスタイプを設定できるはずです。

またはt3、出力を次のように変更することで、出力をフィルタリングして、インスタンスファミリを提供できるAZのリストだけに減らすこともできます。

output "foo" {
  value = keys({ for az, details in data.aws_ec2_instance_type_offering.example : az => details.instance_type if details.instance_type == "t3.micro" })
}

これにより、t3インスタンスファミリを含まないアベイラビリティーゾーンをスキップして、以下が出力されます。

foo = [
  "us-east-1a",
  "us-east-1b",
  "us-east-1c",
  "us-east-1d",
  "us-east-1f",
]