lispの問題と繰り返しの構築

したがって、ここで何が起こっているのかを理解する方法は、コードに注釈を付けて、コードが何をしているのかを示すことです。これはデバッグの古風な方法のように思えるかもしれませんが、CLのような動的な会話言語では、非常に優れたアプローチです。これは、物事に従来の名前を使用し、従来の独立性を使用して、欠落しているコードのスタブを使用してすべてを実行可能にする関数のバージョンです。

(defvar *word-dict* nil)

(defun set-isa (part-of-speech &rest words)
  (do ((wtail words))
      ((null wtail) nil) 
    (putp part-of-speech *word-dict* wtail)
    (setf wtail (cdr wtail))))

(defun putp (part-of-speech dict thing)
  (format *debug-io* "~&putp: ~A ~A ~A~%" part-of-speech dict thing))

したがって、これは実行可能になり、putp取得したものを引数として出力します。

 > (set-isa 'verb 'talk 'run 'jump )
putp: verb nil (talk run jump)
putp: verb nil (run jump)
putp: verb nil (jump)
nil

したがって、ここで実際にバグのあるコードがなくても、ほぼ確実putpに、問題が何であるかを理解できます。ハッシュテーブルに格納されている値を引数にputp 置き換えます。したがって、テーブルに表示される唯一の値は最後の値です。ですから、それを修正する必要があります。これについては後で行います。

しかし実際には、それだけが問題ではありません。

まず第一に、あなたはdo非常に奇妙な方法で使用しています。の構文ではdo、初期化フォームとステッピングフォームが明示的に許可されているため、本体で行うのではなく、実際にステッピングフォームを使用する必要があります。

(defun set-isa (part-of-speech &rest words)
  (do ((wtail words (rest wtail)))
      ((null wtail) nil) 
    (putp part-of-speech *word-dict* wtail)))

第二に、あなたが呼んでいるputpにあなたのリストのすべての尾：あなたはおそらく、個々の単語にそれを呼び出すことにしたいです。これは、各テールの車を渡すだけで実行できますが、Martin Buchmannが他の回答で指摘しているように、代わりに、リストの要素を反復処理する言語の構成を探すこともできます。そして、これらはたくさんありdolist、そのうちの1つです。

(defun set-isa (part-of-speech &rest words)
  (dolist (word words)
    (putp part-of-speech *word-dict* word)))

そして今

(set-isa 'verb 'talk 'run 'jump )
putp: verb nil talk
putp: verb nil run
putp: verb nil jump
nil

putp呼び出される方法は以前のバージョンと互換性がないことに注意してください。リストの末尾ではなく、単語で呼び出されるようになりました。

それで最後に、putpその作品のバージョンを書いてみましょう。私は最初に非常に素朴なバージョンを書きます：

(defvar *word-dict* (make-hash-table))

(defun putp (part-of-speech dict thing)
  (let ((entries (gethash part-of-speech dict '())))
    (setf (gethash part-of-speech dict) (cons thing entries))))

そして、これは機能しますが、あまり良い方法ではありません。

> (gethash 'verb *word-dict* '())
nil
nil

> (set-isa 'verb 'talk 'run 'jump )
nil

> (gethash 'verb *word-dict* '())
(jump run talk)
t

> (set-isa 'verb 'talk 'run 'jump )
nil

> (gethash 'verb *word-dict* '())
(jump run talk jump run talk)
t

一度だけ実行する限り、それは問題ありません。まあ、私たちはこれよりもうまくいくことができます：

• ハッシュテーブルに格納されているリストに新しいものをプッシュする、より慣用的な方法を使用できます。
• より慣用的でありながら、重複エントリを回避できます。

このような：

(defun putp (part-of-speech dict thing)
  (pushnew thing (gethash part-of-speech dict)))

だから、今：

 > (gethash 'verb *word-dict* '())
nil
nil

> (set-isa 'verb 'talk 'run 'jump )
nil

> (gethash 'verb *word-dict* '())
(jump run talk)
t

> (set-isa 'verb 'talk 'run 'jump )
nil

> (gethash 'verb *word-dict* '())
(jump run talk)

これははるかに優れています。あなたは調べてpush、pushnew彼らが何をしているのか見ることができます。