NodeJSがNPMをすぐに見つけられないIExpressインストール後バッチ

上の答えの理由で何が... 'は、内部コマンドまたは外部コマンド、操作可能なプログラムまたはバッチファイルとして認識されていませんか？どこを説明し、システムおよびユーザー環境変数がWindowsレジストリに保存され、どのようにアップデートすると、それらの上に作られています。また、すでに実行中のプロセスの環境変数を変更できるプロセスはなく、新しいプロセスはそれぞれ、親プロセスの環境変数の現在のリストを継承することも説明しています。

したがって、IExpressインストールプロセスを開始すると、このインストールプロセスは、通常はWindowsエクスプローラーである親プロセスから環境変数を継承しますが、wwwブラウザーやその他のアプリケーションにすることもできます。

IExpressのインストールプロセスの実行msiexec /i node.msiインストールのNode.jsを最も可能性が高いとは、追加または変更のシステムやユーザー環境変数Windowsレジストリインチ ただし、マシン全体および現在のユーザーの永続的な保存環境変数に対するこれらの変更は、すでに実行されているIExpressインストールプロセスのローカル環境変数リストに自動的に引き継がれません。

次にによって開始されたIExpressコマンドラインでインストール処理コマンド処理をcmd /c post_install.bat、Windowsで、現在のために設定した環境変数の新しいコピーを取得するIExpressで動作するようにインストールプロセスを。

したがって、永続的な保存システムとユーザー環境変数、またはMSIEXECプロセスのローカル環境変数のWindowsレジストリで変更されたNode.jsインストールプロセスは、バッチファイルを実行するWindowsコマンドプロセスには表示されません。post_install.bat

ただしnpm、post_install.batによって実行されるバッチファイルは、Node.jsのインストールプロセス中にWindowsレジストリに保存されている環境変数によって異なります。そのため、バッチファイルを実行する前に、ローカル環境変数をシステム変数とユーザー環境変数（この順序で）で更新する必要がありnpmます。

これはpost_install.bat、次のコメント付きコードで拡張することで実行できます。

@echo off
setlocal EnableExtensions DisableDelayedExpansion

rem Set current directory to user's profile directory.
cd /D "%UserProfile%"

rem Make sure the environment variables used to build local PATH from
rem the PATH environment variables currently stored in Windows registry
rem do not already exist with unwanted values.
set "LocalPath="
set "SystemPath="
set "UserPath="

rem Get all system environment variables as currently stored in Windows
rem registry and set them in local environment with exception of system PATH.
for /F "skip=2 tokens=1,2*" %%A in ('%SystemRoot%\System32\reg.exe query "HKLM\System\CurrentControlSet\Control\Session Manager\Environment" 2^>nul') do (
    if /I "%%A" == "Path" (
        set "SystemPath=%%C"
    ) else if /I "%%B" == "REG_SZ" (
        set "%%A=%%C"
    ) else if /I "%%B" == "REG_EXPAND_SZ" (
        call set "%%A=%%C"
    )
)

rem Get all user environment variables as currently stored in Windows
rem registry and set them in local environment with exception of user PATH.
for /F "skip=2 tokens=1,2*" %%A in ('%SystemRoot%\System32\reg.exe query "HKEY_CURRENT_USER\Environment" 2^>nul') do (
    if /I "%%A" == "Path" (
        set "UserPath=%%C"
    ) else if /I "%%B" == "REG_SZ" (
        set "%%A=%%C"
    ) else if /I "%%B" == "REG_EXPAND_SZ" (
        call set "%%A=%%C"
    )
)

rem PATH can contain references to environment variables which can be
rem expanded only after having all environment variables except system
rem and user PATH already set in local environment. Now it is possible
rem to expand the environment variable references in system and user
rem PATH and concatenate them two one PATH set in local environment
rem replacing PATH as inherited from process starting this batch file.

if not defined SystemPath goto ProcessUserPath
call set "LocalPath=%SystemPath%"
if not "%LocalPath:~-1%" == ";" set "LocalPath=%LocalPath%;"

:ProcessUserPath
if not defined UserPath goto SetLocalPath
call set "LocalPath=%LocalPath%%UserPath%"

:SetLocalPath
if not defined LocalPath goto DoInstall
if "%LocalPath:~-1%" == ";" set "LocalPath=%LocalPath:~0,-1%"
if defined LocalPath set "PATH=%LocalPath%"

:DoInstall
rem Call NPM in its own environment inherited from current local environment.
rem Then discard all modifications made by NPM batch file on its own local
rem environment and restore the environment this batch file has set before.
setlocal
call npm.cmd install ...
endlocal

rem Insert here other post installation commands.


rem Restore previous environment on starting this batch file which means
rem discarding all modifications made on local list of environment variables
rem and restoring initial current directory before modification by CD at top
rem and restoring initial status of command extensions and delayed expansion.
endlocal

このバッチファイル読み取りシステムとユーザー環境変数は、現在Windowsレジストリに保存されており、ローカルを含むローカル 環境変数を更新しますが、Windows XP / Server2003ではWindowsVista /と比較してREGのPATH出力が異なります。 Server2008以降のすべてのWindowsバージョン。

使用するコマンドとその動作を理解するには、コマンドプロンプトウィンドウを開き、そこで次のコマンドを実行して、各コマンドに表示されるすべてのヘルプページを注意深く読んでください。

• call /?
• cd /?
• echo /?
• endlocal /?
• for /?
• if /?
• reg /?
• reg query /?
• rem /?
• set /?
• setlocal /?