子ノードに複数の親がある場合、Neo4J / Cypherを使用した大量の冗長パス分析を回避するにはどうすればよいですか？

[更新しました]

最古の世代の祖先

このアプローチは、検索対象の最も古い世代の祖先のみが必要な場合に役立ちます。世代を超えてクエリを生成するのは簡単です。

id「id1」であるノードから4世代離れた祖先を検索するとします。

MATCH (:LevelOne { id: "id1" })-[:ISCHILDOF]->(parent:LevelTwo)
WITH DISTINCT parent AS ancestor
MATCH (ancestor)-[:ISCHILDOF]->(parent:LevelTwo)
WITH DISTINCT parent AS ancestor
MATCH (ancestor)-[:ISCHILDOF]->(parent:LevelTwo)
WITH DISTINCT parent AS ancestor
MATCH (ancestor)-[:ISCHILDOF]->(parent:LevelTwo)
RETURN DISTINCT parent AS ancestor;

多くのMATCH句は、世代数に対応しています。

このコンソールは、このアプローチを5世代にわたって示しています。

すべての世代の祖先（最も古い世代へのパス上にない場合でも）

このアプローチは、すべての世代の祖先を検索する場合に役立ちます。以下の例は4世代用です。

注：このアプローチでは、最古の世代への道を進んでいない人も含め、各世代のすべての祖先が一覧表示されます。

MATCH (:LevelOne { id: "id1" })-[:ISCHILDOF]->(parent:LevelTwo)
WITH COLLECT(DISTINCT parent) AS ancestors
WITH [ancestors] AS generations, ancestors UNWIND ancestors AS ancestor
MATCH (ancestor)-[:ISCHILDOF]->(parent:LevelTwo)
WITH generations, COLLECT(DISTINCT parent) AS ancestors
WITH generations+[ancestors] AS generations, ancestors UNWIND ancestors AS ancestor
MATCH (ancestor)-[:ISCHILDOF]->(parent:LevelTwo)
WITH generations, COLLECT(DISTINCT parent) AS ancestors
WITH generations+[ancestors] AS generations, ancestors UNWIND ancestors AS ancestor
MATCH (ancestor)-[:ISCHILDOF]->(parent:LevelTwo)
WITH generations, COLLECT(DISTINCT parent) AS ancestors
RETURN generations+[ancestors] AS generations;