How can I claim ranges of integers to assign to an entity using a SQL Server stored procedure?

I finally got something I think will work.. First, I grab all of the claimed serial number ranges within the date threshold and sort them by the start number ascending and dump them in a temp table. Then the next part is the key concept.. I can peek at the previous row and the next row. That is a slight performance issue that i have to select from the temp table 3 times. but there really shouldn't be that many in there since i have already narrowed it down to the ones that are greater than the date threshold. then it's just a matter of looking at the cases where there can be gaps.

CREATE     PROCEDURE [dbo].[ClaimSerialNumbers]
    @ListJobId int,
    @NumDaysUnique int,
    @MaxSerialNumber int
as
SET NOCOUNT ON; 
BEGIN TRANSACTION

declare @RecipientCount int = 0
declare @QuantityClaimed int = 0
declare @QuantityNeeded int = 0
declare @Now smalldatetime = getdate()
declare @DateThreshold smalldatetime = dateadd(day, 0-@NumDaysUnique, @Now)
declare @RunningTotal int = 0
declare @UnusedRangeCount int = 0

--***************************************
-- Get number of recipients for list job
--***************************************
select  @RecipientCount = coalesce(count(*), 0)
from    dbo.Recipient with(nolock)
where   ListJobId = @ListJobId

--***************************************
-- get how many serial numbers are already claimed
--***************************************
select  @QuantityClaimed = coalesce(sum(SR.SerialNumberEnd - SR.SerialNumberStart + 1), 0)
from    dbo.ListJobSerialRange SR
where   ListJobId = @ListJobId

--***************************************
-- Determine how many we still need
--***************************************
set @QuantityNeeded = @QuantityClaimed - @RecipientCount    

--***************************************
-- if we have more claimed that number of recipients
-- we have deleted recipients and need to free up 
-- some serial numbers
--***************************************
if (@QuantityNeeded < 0) begin
    delete  dbo.ListJobSerialRange
    where   ListJobId = @ListJobId

    set @QuantityNeeded = @RecipientCount
end

--***************************************
-- if we need to claim some serial numbers
--***************************************
if (@QuantityNeeded > 0) begin
    if object_id('tempdb..#SortedRanges') is not null drop table #SortedRanges
    if object_id('tempdb..#UnusedRanges') is not null drop table #UnusedRanges
    create table #SortedRanges(RowNumber int, SerialNumberStart int, SerialNumberEnd int)
    create table #UnusedRanges(SerialNumberStart int, SerialNumberEnd int, RunningTotal int)

    --***************************************
    -- put all the existing ranges within the last N days into a temp table
    --***************************************
    insert  #SortedRanges
            (RowNumber, SerialNumberStart, SerialNumberEnd)
    select  RowNumber = row_number() over (order by SerialNumberStart)
                    , SerialNumberStart
                    , SerialNumberEnd
    from    dbo.ListJobSerialRange
    where   DateClaimed >= @DateThreshold
    order by SerialNumberStart

    --***************************************
    -- if no ranges exist in the last N days, then the whole set is available
    --***************************************
    if (@@rowcount = 0)
    begin
        insert  dbo.ListJobSerialRange
                (ListJobId, DateClaimed, SerialNumberStart, SerialNumberEnd)
        values  (@ListJobId, @Now, 1, @QuantityNeeded)
    end
    --***************************************
    -- if we have serial numbers that were used in the last n days
    -- then look for gaps in the rangesand add those gaps to the unused range temp table
    --***************************************
    else 
    begin
        ;with UnusedRangesFirstPass as (
            select  distinct
                    case 
                        -- start of range (gap at beginning)
                        when P.RowNumber is null and C.SerialNumberStart > 1 then 1
                        -- start of range (gap at end)
                        when N.RowNumber is null and C.SerialNumberEnd < @MaxSerialNumber then C.SerialNumberEnd + 1
                        -- start of range (middle row gaps)
                        else
                            case 
                                when P.SerialNumberEnd is not null and P.SerialNumberEnd < C.SerialNumberStart - 1 then P.SerialNumberEnd + 1
                                when N.SerialNumberStart is not null and N.SerialNumberStart > C.SerialNumberEnd + 1 then C.SerialNumberEnd + 1
                            end
                    end as UnusedStart,
                    case
                        -- end of range (gap at beginning)
                        when P.RowNumber is null and C.SerialNumberStart > 1 then (C.SerialNumberStart - 1)
                        -- end of range (gap at end)
                        when N.RowNumber is null and C.SerialNumberEnd < @MaxSerialNumber then @MaxSerialNumber
                        -- end of range (middle row gaps)
                        else
                            case
                                when P.SerialNumberEnd is not null and P.SerialNumberEnd < C.SerialNumberStart - 1 then C.SerialNumberStart - 1
                                when N.SerialNumberStart is not null and N.SerialNumberStart > C.SerialNumberEnd + 1 then N.SerialNumberStart - 1
                            end
                    end as UnusedEnd
            from #SortedRanges C -- current row
            left join #SortedRanges P ON P.RowNumber = C.RowNumber - 1 -- peek at previous row
            left join #SortedRanges N ON N.RowNumber = C.RowNumber + 1 -- peek at next row
        )
        insert  #UnusedRanges
                (SerialNumberStart, SerialNumberEnd, RunningTotal)
        select  UnusedStart, UnusedEnd, 0
        from    UnusedRangesFirstPass
        where   UnusedStart is not null 
                and UnusedEnd is not null

        --***************************************
        -- update all unused ranges and calculate a running total
        -- for each row
        --***************************************
        update  #UnusedRanges
        set     @RunningTotal = RunningTotal = @RunningTotal + (SerialNumberEnd - SerialNumberStart + 1)

        --***************************************
        -- claim the unused ranges.
        -- only claim the exact number we need
        --***************************************   
        insert  dbo.ListJobSerialRange
                (ListJobId, DateClaimed, SerialNumberStart, SerialNumberEnd)
        select  @ListJobId, @Now, UR1.SerialNumberStart, 
                case 
                    when UR1.RunningTotal > @QuantityNeeded then UR1.SerialNumberEnd - (UR1.RunningTotal - @QuantityNeeded)
                    else UR1.SerialNumberEnd
                end
        from    #UnusedRanges UR1
                left join #UnusedRanges UR2 on UR1.RunningTotal > UR2.RunningTotal
        group by UR1.SerialNumberStart, UR1.SerialNumberEnd, UR1.RunningTotal
        having coalesce(sum(UR2.RunningTotal),0) < @QuantityNeeded
    end
end

--***************************************
-- return results and commit
--***************************************   
select  ListJobSerialRangeId, ListJobId, DateClaimed, SerialNumberStart, SerialNumberEnd
from    dbo.ListJobSerialRange
where   ListJobId = @ListJobId

COMMIT TRANSACTION