我正在尝试使用xsl转换基于XML配置文件生成XSL文件。
这是我的意见。
<front>
<sample1/>
<sample2/>
<sample3>
<item1/>
<item2/>
<item3/>
<item4/>
</sample3>
<sample4/>
</front>
我期望得到xsl文件,
<xsl:template match="//div[@class='front']">
<xsl:apply-templates select=".//*[@class='sample1']"/>
<xsl:apply-templates select=".//*[@class='sample2']"/>
<xsl:apply-templates select=".//*[@class='sample3']"/>
<xsl:apply-templates select=".//*[@class='sample4']"/>
</xsl:template>
<xsl:template match="//*[@class='sample3']">
<xsl:apply-templates select=".//*[@class='item1']"/>
<xsl:apply-templates select=".//*[@class='item2']"/>
<xsl:apply-templates select=".//*[@class='item3']"/>
<xsl:apply-templates select=".//*[@class='item4']"/>
</xsl:template>
这可以使用xsl转换完成吗?主要思想是每当我在配置文件中进行更改时,都无需编写xsl文件。它应该被生成。如果我进行更改,
<front>
<sample1/>
<sample2/>
<sample4/>
<sample3>
<item1/>
<item2/>
<item4/>
<item3/>
</sample3>
</front>
xsl应该是
<xsl:template match="//div[@class='front']">
<xsl:apply-templates select=".//*[@class='sample1']"/>
<xsl:apply-templates select=".//*[@class='sample2']"/>
<xsl:apply-templates select=".//*[@class='sample4']"/>
<xsl:apply-templates select=".//*[@class='sample3']"/>
</xsl:template>
<xsl:template match="//*[@class='sample3']">
<xsl:apply-templates select=".//*[@class='item1']"/>
<xsl:apply-templates select=".//*[@class='item2']"/>
<xsl:apply-templates select=".//*[@class='item4']"/>
<xsl:apply-templates select=".//*[@class='item3']"/>
</xsl:template>
任何帮助将不胜感激。提前致谢!
在XSLT规范本身中,有一个使用XSLT生成样式表的示例:https ://www.w3.org/TR/xslt/#element-namespace-alias
尝试类似的东西:
XSLT 1.0
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:axsl="http://www.w3.org/1999/XSL/TransformAlias">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>
<xsl:namespace-alias stylesheet-prefix="axsl" result-prefix="xsl"/>
<xsl:template match="/">
<axsl:stylesheet version="1.0">
<xsl:apply-templates/>
</axsl:stylesheet>
</xsl:template>
<xsl:template match="/*">
<axsl:template match="div[@class='{name()}']">
<xsl:apply-templates mode="apply"/>
</axsl:template>
<xsl:apply-templates select="*[*]"/>
</xsl:template>
<xsl:template match="*">
<axsl:template match="*[@class='{name()}']">
<xsl:apply-templates mode="apply"/>
</axsl:template>
<xsl:apply-templates select="*[*]"/>
</xsl:template>
<xsl:template match="*" mode="apply">
<axsl:apply-templates select=".//*[@class='{name()}']"/>
</xsl:template>
</xsl:stylesheet>
注意事项:
//
比赛模式中的领先优势完全是多余的;
您确定要.//
在xsl:apply-templates
select
表达式中包含它吗?
本文收集自互联网,转载请注明来源。
如有侵权,请联系[email protected] 删除。
我来说两句