在没有数据源的情况下在ComboBox上设置DisplayMember和ValueMember

从根本上讲，您不能做自己想做的事情：

ValueMember= "Fixed"  
DisplayMember= "Specific and unique number"

Value-和（DisplayMember不是用于指定文字值），而是用于在其他内容（例如类）中指示属性名称。

不使用DataSource（标题）与不使用类（问题文本）是不同的。有创建类的替代方法：

现有的NET类型

您可以使用现有的NETKeyValuePair类将值链接到名称：

cbox.Items.Add(New KeyValuePair(Of String, String)("Specific", 
         "Specific and unique number"))
cbox.Items.Add(New KeyValuePair(Of String, String)("Multiple", 
         "Multiple and different numbers"))
cbox.Items.Add(New KeyValuePair(Of String, String)("Repeated", 
         "One number repeated x times"))

cbox.ValueMember = "Key"
cbox.DisplayMember = "Value"

没有DataSource-数据在items集合中。还有Tuple另一个答案中解释的

匿名类型

使用一个字符串作为另一个字符串的键是很奇怪的。通常，在代码中，您会希望避免打字错误引起的错误。在某处键入“ Fized”会破坏您的代码。一个Enum更有意义：

Private Enum ValueStyle
    Specific = 0
    Multiple = 1
    Repeated = 2
End Enum

现在，您可以创建一个List链接用户描述和Enum常量的：

' fuller text descr of the enum for the user
Dim descr As String() = {"Specific and unique number",
                         "Multiple and different numbers",
                         "One number repeated x times"}
' get enum values into an array of ValueStyle
Dim values = [Enum].GetValues(GetType(ValueStyle)).Cast(Of ValueStyle).ToArray

' create a List of anon objects from the descr() and values()
Dim lst = values.Select( Function (q) New With
                       {.Value = q, .Name = descr (q)}
                    ).ToList()
    
cboPicker.ValueMember = "Value"
cboPicker.DisplayMember = "Name"
cboPicker.DataSource = lst

这将创建一个匿名类型-一个没有类的对象-带有映射到Enum和description数组的Name和Value属性。如果这些Enum值不是连续的（例如{8，65，99}），则列表的构建必须不同。

这将创建一个匿名类型对象的临时集合，并将其分配为DataSource。您将无法访问其他方法中的Name和Value属性，因为无法将匿名类型传递给其他方法。但是用户将看到所需的文本，并且NET / VB将提供作为枚举值的SelectedValue。使用SelectedValue更改的事件：

' name user sees == cboPicker.Text
' value == cboPicker.SelectedValue boxed as Object

Dim userChoice As ValueStyle = CType(cboPicker.SelectedValue, ValueStyle)
If userChoice = ValueStyle.Specific Then
    '...
ElseIf userChoice = ValueStyle.Repeated Then
    '...
End If

请注意，该代码不是使用“ Fixed”作为字符串进行测试，而是使用枚举，但仍具有可读性。

MSDN：匿名类型（Visual Basic）

那些符合不需要新课程的标准，但请考虑：

Friend Class NameValuePair
    Public Property Name As String
    Public Property Value As Int32

    Public Sub New(n As String, v As Int32)
        Name = n
        Value = v
    End Sub

    Public Overrides Function ToString() As String
        Return Name
    End Function

End Class

该类非常简单，并且在将anyName与any关联时几乎可以无限重用Value。它可以与任何数量的项目中的任何数量的基于列表的控件一起使用。创建和使用它们的列表的代码比使用其他方法更简单。