for语句的Coffeescript语法问题

这里有很多问题：

1. 仅then在使用a = if b then c else d单线（例如）时使用，如果您使用的多行形式，if则不使用then。
2. 您的else意思是有多个分支else if。
3. &并且&&是不同的东西，&是按位运算符，&&是您要寻找的逻辑合取。
4. 您需要非常小心并与您的缩进一致。

将这些调整应用于您的代码，您将得到：

for set in datasets
    line.push
        data: set,
        lines:
            show: true
            fill: true
            opacity: 0.7
            fillColor: if lastVisibilty == 0 && curr_visibility == 0 
                "#C90E30"
            else if lastVisibilty == 0 && curr_visibility == 1
                "#439C32"
            else if lastVisibilty == 1 && curr_visibility == 0
                "#C90E30"
            else
                "#439C32"

但是，循环内的条件逻辑并不依赖set（即循环不变），因此您应将其排除在外：

fillColor = if lastVisibilty == 0 && curr_visibility == 0 
        "#C90E30"
    else if lastVisibilty == 0 && curr_visibility == 1
        "#439C32"
    else if lastVisibilty == 1 && curr_visibility == 0
        "#C90E30"
    else
        "#439C32"
for set in datasets
    line.push
        data: set,
        lines:
            show: true
            fill: true
            opacity: 0.7
            fillColor: fillColor

或者更好的方法是，将所有不变的内容推入循环之外，以进一步阐明代码：

fillColor = if lastVisibilty == 0 && curr_visibility == 0 
        "#C90E30"
    else if lastVisibilty == 0 && curr_visibility == 1
        "#439C32"
    else if lastVisibilty == 1 && curr_visibility == 0
        "#C90E30"
    else
        "#439C32"
lines =
    show: true
    fill: true
    opacity: 0.7
    fillColor: fillColor
for set in datasets
    line.push
        data: set,
        lines: lines

或者，由于for循环是一个表达式，您可以这样说：

fillColor = if lastVisibilty == 0 && curr_visibility == 0 
        "#C90E30"
    else if lastVisibilty == 0 && curr_visibility == 1
        "#439C32"
    else if lastVisibilty == 1 && curr_visibility == 0
        "#C90E30"
    else
        "#439C32"
lines =
    show: true
    fill: true
    opacity: 0.7
    fillColor: fillColor
line = ({ data: set, lines: line } for set in datasets)

假设line在循环之前那是空的；如果不是，那么您可以使用Array.prototype.concat：

line = line.concat({data: set, lines: line } for set in datasets)

将循环的数据附加到line。