如何在Ada中明确显示泛型类型的大小？

Alex 发表于 Dev

亚历克斯

我正在尝试编译此代码：https : //github.com/RanaExMachina/ada-fuse

不幸的是，在构建时出现此错误：

fuse-system.ads:147:04: size clause not allowed for variable length type

这似乎是一个问题，因为它在代码中尝试设置具有通用类型作为条目的记录的大小。这似乎是一个新的错误，因为开发人员在2.5年前写的时候就没有这个问题。不幸的是，他无法在短时间内帮助我，但我必须继续努力。但是，我在解决此问题上有点无奈。

基本上，在我看来，我必须以某种方式告诉gnat这种类型的大小，这与gnat的看法相反，是先验的：它是一种访问类型。无论是在record或泛型类型定义。

相关部分是：

fuse-main.ads:
  package Fuse.Main is
    package IO is
      new Ada.Direct_IO (Element_Type);
    type File_Access is access IO.File_Type;

fuse-system.ads:
  generic
    type File_Access is private;
  package Fuse.System is
  ...
    type File_Info_Type is record
      Flags       : Flags_Type;
      Fh_Old      : Interfaces.C.unsigned_long;
      Writepage   : Interfaces.C.int;
      Direct_IO   : Boolean := True;
      Keep_Cache  : Boolean := True;
      Flush       : Boolean := True;
      Nonseekable : Boolean := True;
      Fh          : File_Access;
      Lock_Owner  : Interfaces.Unsigned_64;
    end record;
  type File_Info_Access is access File_Info_Type;
  pragma Convention (C, File_Info_Type);
  for File_Info_Type'Size use 32*8;

我的版本是：4.9.2-1（debian jessie）

西蒙·赖特

您知道这File_Access是一种访问类型，但是在Fuse.System编译器中则不是。它所知道的就是它是确定的，并且支持赋值和相等性。实际可能是数百个字节。

要告诉编译器它是一种访问类型，请尝试以下操作（为方便起见，我在Mac OS X上将其压缩为一个包，因此为64位指针大小；可以编译）：

with Ada.Text_IO;
package Fuse_Tests is

   generic
      type File_Type is limited private;
      type File_Access is access File_Type;
   package Fuse_System is
      type File_Info_Type is record
         Fh : File_Access;
      end record;
      for File_Info_Type'Size use 64;
   end Fuse_System;

   type File_Access is access Ada.Text_IO.File_Type;

   package My_Fuse_System is new Fuse_System
     (File_Type   => Ada.Text_IO.File_Type,
      File_Access => File_Access);

end Fuse_Tests;

或者，在注释中建议一个替代方案：

with Ada.Text_IO;
package Fuse_Tests is

   generic
      type File_Type;
   package Fuse_System is
      type File_Access is access File_Type;
      type File_Info_Type is record
         Fh : File_Access;
      end record;
      for File_Info_Type'Size use 64;
   end Fuse_System;

   package My_Fuse_System is new Fuse_System
     (File_Type => Ada.Text_IO.File_Type);

   --  if needed ...
   subtype File_Access is My_Fuse_System.File_Access;

end Fuse_Tests;