如何使用Web :: Scraper解析此HTML？

user1768233 发表于 Dev

用户名

我正在尝试使用Web :: Scraper解析以下HTML：

<div>
<p><strong>TITLE1</strong>
<br>
DESCRIPTION1
</p>
<p><strong>TITLE2</strong>
<br>
DESCRIPTION2
</p>
<p><strong>TITLE3</strong>
<br>
DESCRIPTION3
</p>
</div>

进入

      'test' => [
                  {
                    'name' => 'TITLE1',
                    'desc' => 'DESCRIPTION1 '
                  },
                  {
                    'name' => 'TITLE2',
                    'desc' => 'DESCRIPTION2 '
                  },
                  {
                    'name' => 'TITLE3',
                    'desc' => 'DESCRIPTION3 '
                  }
                ]

我有以下代码，但运气不佳。处理'p'时的'TEXT'既给出了文本，又给出了介于“ strong”之间的内容

      'test' => [
                  {
                    'name' => 'TITLE1',
                    'desc' => 'TITLE1 DESCRIPTION1 '
                  }
                ]

加上其唯一的第一项。

这是我的代码。

use strict;
use Web::Scraper;
use Data::Dumper;

my $html = q[<div>
            <p><strong>TITLE1</strong>
            <br>
            DESCRIPTION1
            </p>
            <p><strong>TITLE2</strong>
            <br>
            DESCRIPTION2
            </p>
            <p><strong>TITLE3</strong>
            <br>
            DESCRIPTION3
            </p>
           </div>
           ];

 my $test = scraper {
 process 'div', 'test[]' => scraper {
    process 'p strong', 'name' => 'TEXT';
    process 'p','desc' => 'TEXT';       
   };
 };

  my $res = $test->scrape(\$html);
  print Dumper($res);

谢谢你。

津巴布韦

您的代码中有两点需要更改。

要仅获取DESCRIPTION -text，请使用xpath。//p/text()会在any的正下方提供文本节点p，因此strong不包含内的文本节点。

要使所有p显示块（不仅是第一个）都显示在数组中，请使第一个指令处于on位置div p。这样，它就可以抓住a的所有p内部，div而不仅仅是一个div。

my $test = scraper {
    process 'div p', 'test[]' => scraper {
        process 'p strong',           'name' => 'TEXT';
        process '//p/text()', 'desc' => ['TEXT', sub { s/^\s+|\s+$//g } ];
    };
};

输出（带有Data :: Printer）：

\ {
    test   [
        [0] {
            desc   "DESCRIPTION1",
            name   "TITLE1"
        },
        [1] {
            desc   "DESCRIPTION2",
            name   "TITLE2"
        },
        [2] {
            desc   "DESCRIPTION3",
            name   "TITLE3"
        }
    ]
}