如何删除不为空的整个目录？

Chen Yu 发表于 Dev

Chen Yu

我想清理临时资源。该file模块只有del_dir / 1，要求目录为空。但是没有获取目录中所有文件的功能（带有绝对路径”）

源代码如下，该如何纠正？

 delete_path(X)->
    {ok,List} = file:list_dir_all(X), %% <--- return value has no absolute path here
    lager:debug("_229:~n\t~p",[List]),
    lists:map(fun(X)->
                      lager:debug("_231:~n\t~p",[X]),
                        ok = file:delete(X)
                end,List),
    ok = file:del_dir(X),
    ok.

丹尼尔·奥尼琴科（Danil Onishchenko）

您可以使用os：cmd通过控制台命令删除目录，尽管这是一种粗略的方法。对于类似Unix的操作系统，它将是：

os:cmd("rm -Rf " ++ DirPath).

如果要使用适当的erlang函数删除非空目录，则必须递归执行。从下面的例子在这里展示了如何做到这一点：

-module(directory).
-export([del_dir/1]).

del_dir(Dir) ->
   lists:foreach(fun(D) ->
                    ok = file:del_dir(D)
                 end, del_all_files([Dir], [])).

del_all_files([], EmptyDirs) ->
   EmptyDirs;
del_all_files([Dir | T], EmptyDirs) ->
   {ok, FilesInDir} = file:list_dir(Dir),
   {Files, Dirs} = lists:foldl(fun(F, {Fs, Ds}) ->
                                  Path = Dir ++ "/" ++ F,
                                  case filelib:is_dir(Path) of
                                     true ->
                                          {Fs, [Path | Ds]};
                                     false ->
                                          {[Path | Fs], Ds}
                                  end
                               end, {[],[]}, FilesInDir),
   lists:foreach(fun(F) ->
                         ok = file:delete(F)
                 end, Files),
   del_all_files(T ++ Dirs, [Dir | EmptyDirs]).