OCaml：如何正确处理总和类型？

dorafmon 发表于 Dev

多拉蒙

假设我有以下代码：

type s = A of a | B of b


let foo (a:?) = 

let bar (input:s) = match input with
| A a -> foo input
| B b -> ...

我的问题是我应该在foo的签名中填写问号，这样我就不需要（冗余）match语句了吗？还是有更好的模式来做到这一点？

Didierc

如果您想避免重新比赛，我会看到3个解决方案：

使函数foo简单地采用值构造函数的“有效负载” A，并重建类型的值s作为其输出（或与的输出类型匹配的任何其他类型bar）。

# type a;;
type a
# type b;;
type b


# module Ex1 = struct

  type s = A of a | B of b


  let foo (a:a) = A a

  let bar (input:s) = match input with
  | A a -> foo a
  | B b -> (* ... *) input
end;;

module Ex1 :
sig
  type s = A of a | B of b 
  val foo : a -> s 
  val bar : s -> s 
end

使用多态变体：

# module Ex2 = struct

  type s = [ `A of a | `B of b ]

  let foo (`A a) = `A a

  let bar (input:s) = match input with
    | `A _ as a -> foo a
    | `B b -> (* ... *) input
 end;;
 module Ex2 :
 sig
   type s = [ `A of a | `B of b ]
   val foo : [< `A of 'a ] -> [> `A of 'a ]
   val bar : s -> s
 end

使用GADT：

# module Ex3 = struct

  type _ s = 
  | A : a -> a s 
  | B : b -> b s


  let foo (a: a s) : a s = 
    match a with
    | A a -> A a

  let bar: type x.  x s -> x s = fun input ->
    match input with
    | A _ as a -> foo a
    | B b -> (* ... *) input

 end;;
 module Ex3 :
 sig
   type _ s = A : a -> a s | B : b -> b s
   val foo : a s -> a s
   val bar : 'x s -> 'x s
 end