引发的原因和无效的rowid错误

Wamglind Carmasaic 发表于 Dev

Wamglind carmasaic

我试图将每个客户的年龄增加1并显示出来；使用光标。

这是表格结构。

Select * from customers;

+----+----------+-----+-----------+----------+
| ID | NAME     | AGE | ADDRESS   | SALARY   |
+----+----------+-----+-----------+----------+
|  1 | Ramesh   |  32 | Ahmedabad |  2000.00 |
|  2 | Khilan   |  25 | Delhi     |  1500.00 |
|  3 | kaushik  |  23 | Kota      |  2000.00 |
|  4 | Chaitali |  25 | Mumbai    |  6500.00 |
|  5 | Hardik   |  27 | Bhopal    |  8500.00 |
|  6 | Komal    |  22 | MP        |  4500.00 |

这是我的代码：

DECLARE
   c_id customers.id%TYPE;
   c_name customers.name%TYPE;
   c_age customers.age%TYPE;

   CURSOR c1 IS
    SELECT id, name, age
      FROM customers
       FOR UPDATE OF salary;
BEGIN
   OPEN c1;
   LOOP
       FETCH c1 INTO c_id, c_name, c_age;
       UPDATE customers
       SET age = age + 1
       WHERE CURRENT OF c1;

       EXIT WHEN c1%NOTFOUND;
       dbms_output.put_line( c_id || ' ' || c_name || ' ' || c_age );
   END LOOP;
   CLOSE c1;
END;
/

但是，我收到以下错误：

Error report:
ORA-01410: invalid ROWID
ORA-06512: at line 13
01410. 00000 -  "invalid ROWID"
*Cause:    
*Action:
1 Ramesh 32
2 Khilan 25
3 kaushik 23
4 Chaitali 25
5 Hardik 27
6 Komal 22

为什么会发生这种情况，我该如何制止呢？

亚历克斯·普尔

你把你exit放在错误的地方；之后应该是直的fetch。您正在正确处理六个实际行，但是随后进行了第七次提取-在此之后%notfound将进行true-因此没有要更新的“当前”行。您需要先退出，然后再尝试对该无效行执行任何操作。

BEGIN
   OPEN c1;
   LOOP
       FETCH c1 INTO c_id, c_name, c_age;
       EXIT WHEN c1%NOTFOUND;

       UPDATE customers
       SET age = age + 1
       WHERE CURRENT OF c1;

       dbms_output.put_line( c_id || ' ' || c_name || ' ' || c_age );
   END LOOP;
   CLOSE c1;
END;

希望这只是一个练习，因为这不是进行更新的非常有效的方法。

本文收集自互联网，转载请注明来源。

如有侵权，请联系[email protected] 删除。