如何在Delphi中执行C ++参数数组指针算法

您的代码不正确。您有一个额外的，错误的间接级别。您需要的是指向的静态数组的Double指针，而不是指向的动态数组的指针Double。

请记住，动态数组是作为指向数组第一个元素的指针实现的。因此，就间接而言，您的类型等于指向标量指针的指针。

一种进行方式是声明这样的类型

type
  Pflt_arr = ^Tflt_arr;
  Tflt_arr = array [0..0] of flt;

  Pint_arr = ^Tint_arr;
  Tint_arr = array [0..0] of Integer;

并确保对此代码禁用更改检查。

这将允许您编写：

a^[i]

whena是类型Pflt_array。

而且，如果您写：

inc(a, n);

然后它会递增地址，a由n*sizeof(a^)这是n*sizeof(Tflt_array)这是n*sizeof(flt)*Length(a^))这是n*sizeof(flt)这正是你想要的。

当您提供一个常量表达式作为索引时，这种方法会崩溃。按照这一行：

nc := ip^[1];

在这里，编译器将对象1不在范围内0..0。因此，您不能同时拥有这两种方式。

在这种情况下，您似乎需要破解的前两个元素ip。您可以这样做：

type
  Phuge_int_arr = ^Thuge_int_arr; 
  Thuge_int_arr = array [0..(MaxInt div sizeof(Integer))-1] of Integer;

然后写：

nc := Phuge_int_arr(ip)^[1];

感觉有点混乱。

另一种方法是编写这样的类型：

type
  Pflt_arr = ^Tflt_arr;
  Tflt_arr = array [0..(MaxInt div sizeof(flt))-1] of flt;

这对于所有索引方案都适用，并且可以使范围检查保持启用状态。但这使指针递增更加困难。现在您必须编写：

inc(Pflt(a), n);

总而言之，后一种方法可能是两种弊端中较小的一种。

声明实际存储的代码仍应使用动态数组SetLength等。当您需要Pflt_array或Pint_array强制转换动态数组时：

Pflt_array(dyn_array)

这是可行的，因为动态数组被实现为指向数组第一个元素的指针。

使用该0..0变体，您的代码如下所示：

type
  Pflt = ^flt;
  flt = Double;

  Pflt_arr = ^Tflt_arr;
  Tflt_arr = array [0..0] of flt;

  Pint_arr = ^Tint_arr;
  Tint_arr = array [0..0] of Integer;

  Phuge_int_arr = ^Thuge_int_arr; 
  Thuge_int_arr = array [0..(MaxInt div sizeof(Integer))-1] of Integer;

....

constructor TRefT.Create(const length:integer);
begin
  len := length;
  SetLength(_ip, 2 + (1 shl trunc(ln(length / 4.0) / ln(2.0) + 0.5) shr 1) );
  SetLength(_w, length shr 1);
end;

procedure TRefT.CF(buff: pflt_arr);
begin
  rdft(len, 1, buff, Pint_arr(_ip), Pflt_arr(_w));
end;

procedure TRefT.rdft(n:integer; isgn:integer; a:Pflt_arr; ip:Pint_arr; w:Pflt_arr);
var nw, nc: integer;
    xi: flt;
begin
  nw := Phuge_int_arr(ip)^[0];
  nc := Phuge_int_arr(ip)^[1];
  if n > (nc shl 2) then
  begin
    nc := n shr 2;
    inc(w, nw);
    makect(nc, ip, w);
  end;
end;

procedure TRefT.makect(nc:integer; ip:Pint_arr; c:Pflt_arr);
var j, nch: integer;
    delta: flt;
begin
  Phuge_int_arr(ip)^[1] := nc;
  if nc > 1 then
  begin
    nch := nc shr 1;
    delta := arctan(1.0) / nch;
    c^[0] := cos(delta * nch);
    c^[nch] := 0.5 * c^[0];
    for j := 1 to nch do
    begin
      c^[j] := 0.5 * cos(delta * j);
      c^[nc - j] := 0.5 * sin(delta * j);
    end;
  end;
end;

或使用的替代方法0..(MaxInt div sizeof(scalar))-1如下所示：

type
  Pflt = ^flt;
  flt = Double;

  Pflt_arr = ^Tflt_arr;
  Tflt_arr = array [0..(MaxInt div sizeof(flt))-1] of flt;

  Pint_arr = ^Tint_arr;
  Tint_arr = array [0..(MaxInt div sizeof(Integer))-1] of Integer;

....

constructor TRefT.Create(const length:integer);
begin
  len := length;
  SetLength(_ip, 2 + (1 shl trunc(ln(length / 4.0) / ln(2.0) + 0.5) shr 1) );
  SetLength(_w, length shr 1);
end;

procedure TRefT.CF(buff: pflt_arr);
begin
  rdft(len, 1, buff, Pint_arr(_ip), Pflt_arr(_w));
end;

procedure TRefT.rdft(n:integer; isgn:integer; a:Pflt_arr; ip:Pint_arr; w:Pflt_arr);
var nw, nc: integer;
    xi: flt;
begin
  nw := ip^[0];
  nc := ip^[1];
  if n > (nc shl 2) then
  begin
    nc := n shr 2;
    inc(Pflt(w), nw);
    makect(nc, ip, w);
  end;
end;

procedure TRefT.makect(nc:integer; ip:Pint_arr; c:Pflt_arr);
var j, nch: integer;
    delta: flt;
begin
  ip^[1] := nc;
  if nc > 1 then
  begin
    nch := nc shr 1;
    delta := arctan(1.0) / nch;
    c^[0] := cos(delta * nch);
    c^[nch] := 0.5 * c^[0];
    for j := 1 to nch do
    begin
      c^[j] := 0.5 * cos(delta * j);
      c^[nc - j] := 0.5 * sin(delta * j);
    end;
  end;
end;

随便你！

FWIW，为清晰起见，在移植此代码时，您可能会借此机会将shl 2andshr 2运算更改为算术运算。

您可能不知道的选项根本没有翻译。将原始.c文件编译为对象，然后使用静态链接它们$LINK。

最后的评论是，您被如此古老的Delphi所困扰，真是太可惜了。现代版本具有$POINTERMATH编译器选项。这允许C风格的指针算术和对标量变量的纯指针进行索引。这种移植任务的巨大福音。