需要一个SQL Server函数将本地日期时间转换为支持DST的UTC

我们正在将应用程序迁移到Azure，但是当前所有日期都存储为东部标准时间。由于SQL Azure在UTC上，并且我们的许多日期都是通过getdate（）调用生成的，因此，如果我们将所有内容保持原样，都会遇到问题。看来，最不会造成长期困扰的选项是将所有存储的日期都转换为UTC，并在前端将其转换为本地时间。

不幸的是，似乎没有内置的方法可以将SQL日期时间从一个时区转换为另一个时区，而我发现的许多解决方案都没有考虑夏令时。我发现确实考虑DST的解决方案涉及导入日历和时区表，并且非常复杂。

我只是在寻找可以一次转换的东西，而且不一定漂亮。有任何想法吗？

更新：我编写了以下函数，我相信它将完成我所需要的。有人看到这个有漏洞吗？我目前所有的日期均为东部标准时间，但我的日期始于2002年左右，所以我不得不在2007年处理该法律变更。

我在想我会像这样使用此功能：

UPDATE myTable SET myDate = dbo.fnESTtoUTC(myDate)

功能如下：

CREATE FUNCTION [dbo].[fnESTtoUTC]
    (@pESTDate  DATETIME)
    RETURNS DATETIME
AS
BEGIN

DECLARE @TimeZoneOffset INT
DECLARE @Year INT
DECLARE @Day INT
DECLARE @DSTStart DATETIME
DECLARE @DSTEnd DATETIME

SELECT @Year = DATEPART(year, @pESTDate)

IF @Year >= 2007
BEGIN
    SELECT @Day = 8
    WHILE @DSTStart IS NULL
    BEGIN
        -- Second Sunday in March
        IF DATEPART(weekday, DATEFROMPARTS(@Year, 3, @Day)) = 1
            SELECT @DSTStart = DATETIMEFROMPARTS(@Year, 3, @Day, 2, 0, 0, 0)
        SELECT @Day = @Day + 1
    END

    SELECT @Day = 1
    WHILE @DSTEnd IS NULL
    BEGIN
        -- First Sunday in November
        IF DATEPART(weekday, DATEFROMPARTS(@Year, 11, @Day)) = 1
            SELECT @DSTEnd = DATETIMEFROMPARTS(@Year, 11, @Day, 1, 0, 0, 0)
        SELECT @Day = @Day + 1
    END
END
ELSE
BEGIN
    SELECT @Day = 1
    WHILE @DSTStart IS NULL
    BEGIN
        -- First Sunday in April
        IF DATEPART(weekday, DATEFROMPARTS(@Year, 4, @Day)) = 1
            SELECT @DSTStart = DATETIMEFROMPARTS(@Year, 4, @Day, 2, 0, 0, 0)
        SELECT @Day = @Day + 1
    END

    SELECT @Day = 31
    WHILE @DSTEnd IS NULL
    BEGIN
        -- Last Sunday in October
        IF DATEPART(weekday, DATEFROMPARTS(@Year, 10, @Day)) = 1
            SELECT @DSTEnd = DATETIMEFROMPARTS(@Year, 10, @Day, 1, 0, 0, 0)
        SELECT @Day = @Day - 1
    END
END

IF @pESTDate >= @DSTStart AND @pESTDate < @DSTEnd
BEGIN
    -- Date is in DST
    SELECT @TimeZoneOffset = 4
END
ELSE
BEGIN
    -- Not DST
    SELECT @TimeZoneOffset = 5
END

RETURN ( dateadd(hh, @TimeZoneOffset, @pESTDate) )
END