如何使用SAS从Web下载文件并将其分配到特定文件夹

supercool djkazu 发表于常见问题

过冷的djkazu

早上好

因此，我尝试从网站上下载zip文件，并尝试分配位置。

我要放的位置是

S:\Projects\

方法1，

第一次尝试低于

DATA _null_ ;
x 'start https://yehonal.github.io/DownGit/#/home?url=https:%2F%2Fgithub.com%2FCSSEGISandData%2FCOVID-19%2Ftree%2Fmaster%2Fcsse_covid_19_data%2Fcsse_covid_19_daily_reports';
RUN ;

方法1，我可以下载文件，但是会自动下载到我的“下载”文件夹中。

方法2

所以我发现了

filename out "S:\Projects\csse_covid_19_daily_reports.zip";

proc http
 url='https://yehonal.github.io/DownGit/#/home?url=https:%2F%2Fgithub.com%2FCSSEGISandData%2FCOVID-19%2Ftree%2Fmaster%2Fcsse_covid_19_data%2Fcsse_covid_19_daily_reports'
 method="get" out=out;
run;

但是代码不起作用，没有下载任何东西。

如何从网上下载文件并分配到特定位置？

里扎

在这种情况下，我可能会建议一个宏（或CALL EXECUTE），但我更喜欢宏，然后通过CALL EXECUTE调用该宏。在SAS Academics on Demand（免费云服务）上运行了大约一分钟。

*set start date for files;
%let start_date = 01-22-2020;

*macro to import data;
%macro importFullData(date);
    *file name reference;
    filename out "/home/fkhurshed/WANT/&date..csv";
    *file to download;
    %let download_url = "https://raw.githubusercontent.com/CSSEGISandData/COVID-19/master/csse_covid_19_data/csse_covid_19_daily_reports/&date..csv";

    proc http url=&download_url
 method="get" out=out;
    run;

    *You can add in data import/append steps here as well as necessary;
%mend;

%importFullData(&start_date.);

data importAll;
    
    start_date=input("&start_date", mmddyy10.);
    *runs up to previous day;
    end_date=today() - 1;

    do date=start_date to end_date;
        formatted_date=put(date, mmddyyd10.);
        str=catt('%importFullData(', formatted_date, ');');
        call execute(str);
    end;
run;