使用权。如何在 CBO 中创建记录并在另一个表单上选择该记录？

debugcn 发表于 Dev

坦济布

我有两种形式frmProductCreate和frmColourCreate。

在frmProductCreate我有：

组合框： colourID
按钮： btnColCreate

这个想法是，如果用户需要创建新颜色，他们可以单击打开的创建按钮frmColourCreate，命名新颜色并单击保存按钮。这将在颜色表中保存新颜色（这是 cbo ColourIDin的记录源frmProductCreate）。然后再次查询colourID中frmProductCreate并关闭frmColourCreate。

我还希望这个保存按钮做的是在重新查询之后选择 cbocolourID并转到最后创建的颜色。即最后一条记录。我尝试了一些代码，但未能使其正常工作。任何帮助将不胜感激。

Private Sub btnSavecol_Click()
    Dim cancel As Integer

    If Me.ColName = "" Then
        MsgBox "You must enter a Colour Name."
        DoCmd.GoToControl "ColName"

        cancel = True
    Else
        If MsgBox("Are you sure you want to create new Colour?", vbYesNo) = vbNo Then
            cancel = True
        Else
            CurrentDb.Execute " INSERT INTO Colours (ColName) VALUES ('" & Me.ColName & "')"

            Me.ColName = ""

            DoCmd.Close

            If CurrentProject.AllForms("frmProductCreate").IsLoaded = False Then
                cancel = True
            Else
                Forms!frmproductCreate!ColourID.Requery
                'Forms!frmproductCreate!ColourID.SetFocus
                'Forms!frmproductCreate!ColourID.items.Count = -1
                'Forms!frmproductCreate!ColourID.Selected(Forms!frmproductCreate!ColourID.Count - 1) = False

                'YourListBox.SetFocus
                'YourListBox.ListIndex = YourListBox.ListCount - 1
                'YourListBox.Selected(YourListBox.ListCount - 1) = False
            End If

            If CurrentProject.AllForms("frmProductDetails").IsLoaded = False Then
                cancel = True
            Else
                Forms!frmproductDetails!ColourID.Requery
            End If
        End If
    End If
End Sub

未处理的异常

一些备注：

变量是cancel什么？因为没用，所以删了。
我真的不知道你需要什么Me.ColName = ""。
你为什么这么早关闭当前的表单？我DoCmd.Close走到了尽头。
通过删除“箭头代码”（那些嵌套的IFs），我使您的代码更具可读性。

最后试试这个：

Private Sub btnSavecol_Click()
    If Me.ColName.Value = "" Then
        MsgBox "You must enter a Colour Name."
        DoCmd.GoToControl "ColName"
        Exit Sub
    End If

    If MsgBox("Are you sure you want to create new Colour?", vbYesNo) = vbNo Then Exit Sub

    CurrentDb.Execute "INSERT INTO Colours (ColName) VALUES ('" & Me.ColName.Value & "')"

    If Not CurrentProject.AllForms("frmProductCreate").IsLoaded Then GoTo Done

    Forms!frmproductCreate!ColourID.Requery

    'This sets the ComboBox 'ColourID' to the new colour:
    'Forms!frmproductCreate!ColourID.Value = Me.ColName.Value

    'If you use an automatic generated ID in the table 'Colours', then you will have to get that ID from the color and set it to the ComboBox:
    Forms!frmproductCreate!ColourID.Value = DLookup("ColID", "Colours", "ColName = '" & Me.ColName.Value & "'")

    Me.ColName.Value = ""

    If Not CurrentProject.AllForms("frmProductDetails").IsLoaded Then GoTo Done

    Forms!frmproductDetails!ColourID.Requery

Done:
    DoCmd.Close
End Sub

本文收集自互联网，转载请注明来源。

如有侵权，请联系[email protected] 删除。