从行中跳过一些文本

debugcn 发表于 Dev

安东尼奥·巴拉扎特

我需要从行中删除一些文本：

strdir = "C:\texto.txt"
Set fso = CreateObject("Scripting.FileSystemObject")
Set objFile = fso.OpenTextFile(strdir)
Dim arrTxt()
k = 0
Do Until objFile.AtEndOfStream
    z = (k+1)
    ReDim Preserve arrTxt(z)
    line = objFile.ReadLine
    arrTxt(k) = line
    k = z
Loop
print Join(arrTxt, ",") 
print (UBound(arrTxt) + 1)

我的文本文件texto.txt：

名称=测试
[email protected]

我想删除“名称=”和“correo=”。

维佳塔

使用vba - 最初的想法是使代码易于人类理解 - 代码有以下 3 个任务：

从文件中读取并将输入保存为字符串；
操作字符串（例如替换name=和correo=；
将操作后的字符串写入新文件；

所有这些行动在以下方面都很明显TestMe()：

Sub TestMe()

    Dim readTxt As String
    Dim filePath As String: filePath = "C:\text.txt"

    readTxt = ReadFromFile(filePath)
    readTxt = Replace(readTxt, "name=", "")
    readTxt = Replace(readTxt, "correo=", "")

    WriteToFile filePath, readTxt

End Sub

一旦上面的骨头是准备好了，这两个功能ReadFromFile和WriteToFile非常方便：

Public Function ReadFromFile(path As String) As String

    Dim fileNo As Long
    fileNo = FreeFile

    Open path For Input As #fileNo

    Do While Not EOF(fileNo)
        Dim textRowInput As String
        Line Input #fileNo, textRowInput
        ReadFromFile = ReadFromFile & textRowInput
        If Not EOF(fileNo) Then
            ReadFromFile = ReadFromFile & vbCrLf
        End If
    Loop

    Close #fileNo

End Function

Sub WriteToFile(filePath As String, text As String)

    Dim fso As Object
    Set fso = CreateObject("Scripting.FileSystemObject")
    Dim oFile As Object
    Set oFile = fso.CreateTextFile(filePath)
    oFile.Write text
    oFile.Close

End Sub

本文收集自互联网，转载请注明来源。

如有侵权，请联系[email protected] 删除。