使用 SPARQL 查询检索标签名称

debugcn 发表于 Dev

蒂姆·德布鲁恩

我在使用维基数据查询服务时遇到问题。https://query.wikidata.org/我想要做的是检索所有拥有 GTAA ID 的人的列表。

?q wdt:P1741 ?GTAA_ID.

对于这些人，我想检索以下可选信息：

OPTIONAL{ ?q p:P166 ?award_received
OPTIONAL{ ?award_received pq:P585 ?point_in_time. }
OPTIONAL{ ?award_received pq:P1686 ?for_work.   }

获奖
他们是在什么时候获得这个奖项的
他们因为什么工作获得了这个奖项

截至目前，我的查询大多有效。但是，例如，在“awards_received”列中，它显示以下文本：

wds:Q76343-ffa729dc-4d10-eb15-3a41-5fa6bf7ed80a

当点击它时，它会将我带到有关获奖者的维基数据页面，而不是奖项本身的标题。我想要做的是检索获得的奖项的标题，而不是指向标题接收者的链接。

我的代码如下：

SELECT ?GTAA_ID ?award_received ?point_in_time ?for_workLabel
   WHERE
   {
       ?q wdt:P1741 ?GTAA_ID.
       OPTIONAL{ ?q p:P166 ?award_received
       OPTIONAL{ ?award_received pq:P585 ?point_in_time. }
       OPTIONAL{ ?award_received pq:P1686 ?for_work.   }
       . }
       SERVICE wikibase:label { bd:serviceParam wikibase:language "     
       [AUTO_LANGUAGE]". }
   }

埃夫谢诺

实际奖励作为ps:P166声明的财产给出：

SELECT ?GTAA_ID ?award ?awardLabel ?point_in_time ?for_workLabel {
  ?q wdt:P1741 ?GTAA_ID.
  OPTIONAL {
    ?q p:P166 ?award_received .
    ?award_received ps:P166 ?award # Here
    OPTIONAL { ?award_received pq:P585 ?point_in_time. }
    OPTIONAL { ?award_received pq:P1686 ?for_work. }
  }
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE]".
  }
}

您可以通过DESCRIBE查询获取资源的描述，例如：

DESCRIBE wds:Q78217-3877ABD6-239F-47DA-A8BD-8035D3CBAA7A

本文收集自互联网，转载请注明来源。

如有侵权，请联系[email protected] 删除。