仅在 PowerPoint 幻灯片放映中的某些幻灯片上自动暂停播放声音

如果您还没有找到任何解决方案，您可以尝试使用 VBA，使用来自 winmm.dll 的外部 API 函数“MCISendString”。

您应该注意的一件事是“fileToPlay”字符串中不能有任何空格字符。您可以使用另一个名为 OnSlideShowPageChange 的函数来自动播放和恢复音频播放。

#If VBA7 Then
    Declare PtrSafe Function mciSendString Lib "winmm.dll" Alias _
    "mciSendStringA" (ByVal lpstrCommand As String, ByVal _
    lpstrReturnString As Any, ByVal uReturnLength As Long, ByVal hwndCallback As Long) As Long
#Else
    Declare Function mciSendString Lib "winmm.dll" Alias _
    "mciSendStringA" (ByVal lpstrCommand As String, ByVal _
    lpstrReturnString As Any, ByVal uReturnLength As Long, ByVal hwndCallback As Long) As Long

#End If

Sub OnSlideShowPageChange(SSW As SlideShowWindow)

    Dim fileToPlay As String
    Dim MCIAudio As Long

    fileToPlay = Chr(34) & ActivePresentation.Path & "\test.mp3" & Chr(34)

    Select Case SSW.View.CurrentShowPosition
        Case 1:
            'first, close the previous playing and open new and play
            MCIPlay = mciSendString("close MyAudio", Nothing, 0, 0)
            MCIAudio = mciSendString("open " & fileToPlay & " alias MyAudio", Nothing, 0, 0)
            MCIAudio = mciSendString("play MyAudio", Nothing, 0, 0)
        Case 2:
            MCIAudio = mciSendString("pause MyAudio", Nothing, 0, 0)
        Case 3:
            MCIAudio = mciSendString("resume MyAudio", Nothing, 0, 0)
        Case 4:
            MCIAudio = mciSendString("stop MyAudio", Nothing, 0, 0)
    End Select
End Sub

Sub OnSlideShowTerminate()
    Dim MCIAudio As Long

    MCIAudio = mciSendString("stop MyAudio", Nothing, 0, 0)
    MCIAudio = mciSendString("close MyAudio", Nothing, 0, 0)
End Sub

在本例中，在幻灯片 1 上，开始播放。在幻灯片 2 上，暂停播放。在幻灯片 3 上，继续播放。在幻灯片 4 上，停止播放。当幻灯片放映结束时，停止播放。

（您知道，OnSlideShowPageChange 有时无法启动。如果那样，只需在第一张幻灯片上插入任何 Active-X 控件，这是一种已知的解决方法。）

其他 MCISendString 命令可以在这里找到：https ://msdn.microsoft.com/en-us/library/ms710815.aspx