查找包含特定文件的最新文件夹

debugcn 发表于 Dev

拉胡尔克

我需要搜索包含多个文件夹的目录并检查最新文件（.exe）并将其复制到另一个位置。

SET "src_root"
SET "tgt_path"
DIR "%src_root%" /B /AD /O-D /TC > "%TEMP%\dirlist.tmp"
< "%TEMP%\dirlist.tmp" SET /P last_dir=
XCOPY "%src_root%\%last_dir%\*.exe" "%tgt_path%"**

此代码帮助我复制最新文件夹中的 EXE 文件，但如果最新文件夹中没有 EXE，我需要从包含最新 EXE 的文件夹中复制它，有人可以帮我吗？

麻古

@ECHO OFF
SETLOCAL
SET "sourcedir=c:\sourcedir"
SET "filename="

FOR /f "delims=" %%a IN (
 'dir /s /b /a-d "%sourcedir%\neo.7z" '
 ) DO SET "filename=%%a"&set "dirname=%%~dpa"&goto found1

ECHO NOT found!
GOTO :eof

:found1
FOR /f "delims=" %%a IN (
 'dir /s /b /a-d "%sourcedir%\neo.7z" '
 ) DO IF /i "%dirname%" neq "%%~dpa" FOR /f %%s IN ('XCOPY /y /L /D "%filename%" "%%~dpa"') DO IF "%%s"=="0" SET "filename=%%a"&set "dirname=%%~dpa"&goto found1

ECHO latest file is "%filename%"

GOTO :EOF

您需要更改的设置sourcedir以适合您的情况。

我使用了neo.7z为我的测试命名的文件- 我相信在你描述的情况下你应该有一个固定的文件名 - 目录无疑没有塞满 *.exe 文件。

这是非常行人，但会做这项工作。

本质上，在所需的目录树中找到具有所需名称的任何文件，并将名称记录在filename, 目录中dirname。

使用该文件名作为基础，尝试xcopy在所有其他匹配的文件名上使用它。使用该/L标志仅列出，并使用该/y标志去除用户干预。如果返回的是1 file(s) copied,f 其中只有第一个标记被选入%%s，则选择的文件在后。0 file(s) copied设置%%s为0和意味着选择的文件较早，因此选择较新的文件和目录名并重新启动。

我将把它留给用户练习以加快速度。（有兴趣的建议：延迟扩展、子程序和保留新起点）

改版【快5倍左右】

@ECHO OFF
SETLOCAL
SET "sourcedir=c:\sourcedir"
SET "filename="

FOR /f "delims=" %%a IN (
 'dir /s /b /a-d "%sourcedir%\neo.7z" '
 ) DO SET "candidate=%%a"&CALL :latest

ECHO latest file is "%filename%"
GOTO :eof

:latest
IF NOT DEFINED filename GOTO selectnew

FOR /f %%s IN ('XCOPY /y /L /D "%filename%" "%candidate%"') DO IF "%%s"=="1" goto :eof

:selectnew
SET "filename=%candidate%"

GOTO :EOF

此版本避免了重复的目录扫描。对于每个匹配的文件名，使用该xcopy /L方法将新找到的文件与先前找到的文件进行比较，如果新的候选文件较晚，则选择新的候选文件。继续直到所有匹配的名称都经过测试。

本文收集自互联网，转载请注明来源。

如有侵权，请联系[email protected] 删除。