我有一个包含 2 列的文本文件，我想将其转换为表格。下图只是文件中的样子，而不是表格。格式是在发布问题时将我的所有文本放在一行中。
这是文件中数据的样子：
name: name1
copies: 3
copy1: name1copy1
copy2: name1copy2
copy3: name1copy3
name: name2
copies: 1
copy1: name2copy1
name: name3
copies: 2
copy1: name3copy1
copy2: name3copy2
这是我想出去的：
name,copies,copy1,copy2,copy3
name1,3,name1copy1,name1copy2,name1copy3
name2,1,name2copy1,bull,null
name3,2,name3copy1,name3copy2,null
从这里我可以导入到 excel 中。
这将 GNU awk 用于多维数组：它一次性读取所有数据并在 END 块中发出输出。这是“script.awk”
BEGIN {FS = ": "}
!($1 in head) {head[$1] = h++}
$1 == "name" {name = $2}
{data[name][$1] = $2}
END {
PROCINFO["sorted_in"] = "@val_num_asc"
# print the header
sep=""
for (item in head) {
printf "%s%s", sep, item
sep = ","
}
printf "\n"
# print the data
for (name in data) {
sep=""
for (item in head) {
printf "%s%s", sep, data[name][item]
sep = ","
}
printf "\n"
}
}
然后：
$ gawk -f script.awk file
name,copies,copy1,copy2,copy3
name1,3,name1copy1,name1copy2,name1copy3
name2,1,name2copy1,,
name3,2,name3copy1,name3copy2,
本文收集自互联网，转载请注明来源。
如有侵权，请联系[email protected] 删除。
我来说两句