如何根据不同单元格中的特定条目向单元格添加自定义文本？

您可以使用公式执行此操作，只要您不需要编辑结果

• 创建一个表格，用作各个公司的模板。
  • 这可以在单独的工作表上，如果需要，您甚至可以将其隐藏。
• NAME 表，例如： tblTests

它可能看起来像：

• 类似地设置您的工作表，A 列是您填写公司名称的位置，顶部是测试列表。
• 在B2工作表中，输入公式：

对于 O365：

=IFERROR(FILTER(tblTests[[Test1]:[Test20]],tblTests[Company]=A2),"")

对于早期版本：

=IFERROR(INDEX(tblTests[[Test1]:[Test20]],MATCH(A4,tblTests[Company],0),0),"")

并根据需要填写。

（如果您的 Excel 版本没有动态数组，您可能需要在 20 个单元格的整个行段中将其作为数组公式输入）

如果您现在在 A 列中输入公司名称，它将自动使用您设置的模式填充该行。

如果这必须是一个宏，或者如果您在填写单元格后可能需要修改它们，您可以使用类似的方法，使用一个宏引用您在工作簿或代码中设置的查找表，以及让宏由worksheet_change针对 A 列的事件触发

例如，输入以下代码作为Worksheet Code您记录公司的工作表：（请注意，我们仍在工作簿中的某些工作表上使用模板表）

Option Explicit
Option Compare Text

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim R As Range, C As Range, V, I As Long, J As Long
    Dim tblTests As Variant

Set R = Columns(1)
Set C = Intersect(Target, R)
If Not C Is Nothing Then
    If C.Count > 1 Then
        MsgBox "Enter only one company at a time"
        Exit Sub
    End If
    
    'tblTests is on Sheet1
    tblTests = Sheet1.ListObjects("tblTests").DataBodyRange
    
    Application.EnableEvents = False
        With C
            Range(.Cells(1, 2), .Cells(1, 21)).ClearContents
                'with only 20 companies, can loop the table
                'if you have thousands, may be more efficient to read the lookup table into a dictionary
                I = 1
                Do Until tblTests(I, 1) = C.Value
                    I = I + 1
                    If I > UBound(tblTests, 1) Then Exit Do
                Loop
                
                If I > UBound(tblTests, 1) Then
                    If Len(C) > 0 Then .Offset(0, 1) = "Company not in template table"
                Else
                    ReDim V(1 To 21)
                    For J = 1 To 21
                        V(J) = tblTests(I, J)
                    Next J
                    
                    .Resize(columnsize:=21) = V
                End If
            End With
    Application.EnableEvents = True
End If

End Sub