使用外部编辑器编辑Zsh命令并替换原始命令

debugcn 发表于 Dev

用户名

我在Zim中使用Zsh 。我通过将以下内容放入，在Neovim中设置了用于编辑当前命令的键绑定.zshrc：

bindkey -v
export VISUAL=nvim
autoload edit-command-line; zle -N edit-command-line
bindkey -M vicmd v edit-command-line

这样，当我完成命令编辑时，最终结果将放置在原始文件的下面，如下面的屏幕截图所示。

我想要的是最终结果替换了原来的行。这样做的主要原因是我使用的是启用了瞬态提示的Powerlevel10k 。此功能在特定情况下不起作用。

罗马·佩列佩里察（Roman Perepelitsa）

免责声明：我是Powerlevel10k的作者。

启用瞬态提示后，在外部编辑器中完成命令编辑后，Powerlevel10k应该截断提示。但是，事实并非如此。感谢您的举报，我已将其修复。

现在回到您的原始问题。

我想要的是最终结果替换了原来的行。

您需要为此定义一个自定义的zle小部件。这是一个实现：

function edit-command-line-inplace() {
  if [[ $CONTEXT != start ]]; then
    if (( ! ${+widgets[edit-command-line]} )); then
      autoload -Uz edit-command-line
      zle -N edit-command-line
    fi
    zle edit-command-line
    return
  fi
  () {
    emulate -L zsh -o nomultibyte
    local editor=("${(@Q)${(z)${VISUAL:-${EDITOR:-vi}}}}") 
    case $editor in
      (*vim*)
        "${(@)editor}" -c "normal! $(($#LBUFFER + 1))go" -- $1
      ;;
      (*emacs*)
        local lines=("${(@f)LBUFFER}") 
        "${(@)editor}" +${#lines}:$((${#lines[-1]} + 1)) $1
      ;;
      (*)
        "${(@)editor}" $1
      ;;
    esac
    BUFFER=$(<$1)
    CURSOR=$#BUFFER
  } =(<<<"$BUFFER") </dev/tty
}

您可以使用与绑定相同的方法进行绑定edit-command-line：

zle -N edit-command-line-inplace
bindkey -M vicmd v edit-command-line-inplace

请注意，这edit-command-line-inplace取决于edit-command-line不可能就地更新命令行的情况。例如，尝试键入echo 'first line，点击Enter然后调用edit-command-line-inplace。无法更新命令的第一行，因此其edit-command-line-inplace行为与相同edit-command-line。