批次参数不正确

debugcn 发表于 Dev

克尔蒂瓦桑

用户输入参数未设置为checkoutdir变量。

@echo off
echo.
echo. [ SVN Updater ]
setlocal enableDelayedExpansion
set SOURCE=E:\Svncheckout\21MAY2016\
set SVN=C:\Program Files\TortoiseSVN\bin
set SVN_REPO_URL=https://192.168.1.35:8443/svn/
set projects=JPO/JPOMobile/branches/2016-05-18 JPO/JPOWEB/branches/20160518
(for %%i in (%projects%) do (
            echo. Going to repository - %%i
            echo. Please provide checkoutdir name
            set /p checkoutdir= 
            echo. Checking out %SVN_REPO_URL%%%i from SVN...
            "%SVN%\TortoiseProc.exe" /command:checkout /path:"%SOURCE%%checkoutdir%" /url:"%SVN_REPO_URL%%%i" /closeonend:2 
    )
)
echo.
echo. Operation complete.

问题：将checkoutdir设置为项目目录名称对于第一次迭代，将其设置为2016-05-18结果到的路径E:\Svncheckout\21MAY2016\2016-05-18。对于第二次迭代，将其设置为20160518将结果输入到E:\Svncheckout\21MAY2016\20160518

莫菲

此代码应工作：

@echo off
echo.
echo. [ SVN Updater ]
setlocal EnableDelayedExpansion
set "SOURCE=E:\Svncheckout\21MAY2016\"
set "SVN=%ProgramFiles%\TortoiseSVN\bin"
set "SVN_REPO_URL=https://192.168.1.35:8443/svn/"
set "projects=JPO/JPOMobile/branches/2016-05-18 JPO/JPOWEB/branches/20160518"
for %%i in (%projects%) do (
    echo. Going to repository - %%i
    echo. Please provide checkoutdir name
    set /p "checkoutdir=Directory name: "
    echo. Checking out %SVN_REPO_URL%%%i from SVN...
    "%SVN%\TortoiseProc.exe" /command:checkout /path:"%SOURCE%!checkoutdir!" /url:"%SVN_REPO_URL%%%i" /closeonend:2
)
echo.
echo. Operation complete.
endlocal

在启用延迟扩展之后，有必要使用感叹号而不是百分号来引用具有延迟扩展的变量。

打开命令提示符窗口，运行set /?并阅读所有输出页面。

用百分号引用的环境变量总是在解析命令行或使用(...定义的命令块时进行扩展)。

本文收集自互联网，转载请注明来源。

如有侵权，请联系[email protected] 删除。