将驱动器添加到Windows文件资源管理器导航窗格

感谢Simon Mourier及其在Windows资源管理器中将文件夹固定到导航窗格的回答：

PinDiskD.bat。运行以将磁盘固定在“文件资源管理器”导航窗格中D:\上方的某个位置。使用任何非空参数运行，以从窗格中删除磁盘，例如（请注意下面的标签）。This PCD:\PinDiskD.bat x:deleAll

@ECHO OFF
SETLOCAL EnableExtensions
set "_icon=%%SystemRoot%%\system32\imageres.dll,27"
set "_name=d DataDisk"
set "_guid=ffffffff-ffff-ffff-0000-00000000000d"
set "_target=d:\\"

set "_regK=HKCU\Software\Classes\CLSID"
set "_regE=HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer"
if NOT "%~1"=="" goto :deleAll
reg add %_regK%\{%_guid%} /ve /t REG_SZ /d "%_name%" /f
reg add %_regK%\{%_guid%}\DefaultIcon /ve /t REG_EXPAND_SZ /d %_icon% /f
reg add %_regK%\{%_guid%} /v System.IsPinnedToNameSpaceTree /t REG_DWORD /d 0x1 /f
reg add %_regK%\{%_guid%} /v SortOrderIndex /t REG_DWORD /d 0x42 /f
reg add %_regK%\{%_guid%}\InProcServer32 /ve /t REG_EXPAND_SZ /d %%systemroot%%\system32\shell32.dll /f
reg add %_regK%\{%_guid%}\Instance /v CLSID /t REG_SZ /d {0E5AAE11-A475-4c5b-AB00-C66DE400274E} /f
reg add %_regK%\{%_guid%}\Instance\InitPropertyBag /v Attributes /t REG_DWORD /d 0x11 /f
reg add %_regK%\{%_guid%}\Instance\InitPropertyBag /v TargetFolderPath /t REG_EXPAND_SZ /d "%_target%" /f
reg add %_regK%\{%_guid%}\ShellFolder /v FolderValueFlags /t REG_DWORD /d 0x28 /f
reg add %_regK%\{%_guid%}\ShellFolder /v Attributes /t REG_DWORD /d 0xF080004D /f
reg add %_regE%\Desktop\NameSpace\{%_guid%} /ve /t REG_SZ /d "%_name%" /f
reg add %_regE%\HideDesktopIcons\NewStartPanel /v {%_guid%} /t REG_DWORD /d 0x1 /f

:endlocal
ENDLOCAL
goto :eof

:deleAll
reg delete %_regK%\{%_guid%}                                   /f
reg delete %_regE%\Desktop\NameSpace\{%_guid%}                 /f
reg delete %_regE%\HideDesktopIcons\NewStartPanel /v {%_guid%} /f
goto :endlocal

PinDiskC.bat。将磁盘固定C:\在窗格中。除以下四个最重要的命令外，与PinDiskD.bat相同set：

set "_icon=%%SystemRoot%%\system32\imageres.dll,31"
set "_name=c SystemDisk"
set "_guid=ffffffff-ffff-ffff-0000-00000000000c"
set "_target=c:\\"
…

D：\ bat \ PinCodePages.bat。将特定的本地文件夹固定到窗格。作为同PinDiskD.bat除了4个最重要的set命令（的双重检查的有效性_icon，_name，_guid和_target变量）：

set "_icon=%%SystemRoot%%\system32\shell32.dll,176" # any valid icon
set "_name=My Folder"                               # any valid name
set "_guid=ffffffff-ffff-ffff-0000-00000000c0de"    # a valid GUID (no braces)
set "_target=d:\Utils\CodePages\\"                  # any valid local path
…

运行以上所有脚本后，在Windows 10上的显示示例：