使用具有多个条件的xpath从xml文件中提取值

我试图提取指定以下条件的这两个系统[paraview＆Pstoedit]，这两个系统应该具有相同的确切字符串。

您可以通过以下方式选择所有具有匹配系统的Pstoedit系统（或更确切地说，其祖先word）paraview：

/dev/word[systems/system/@name='Pstoedit'][@string=/dev/word[systems/system/@name='paraview']/@string]

输出应该给我匹配的数量，然后说是的，有两个系统要满足您的条件...

好吧，每个选定的节点都代表一对，因此：

2 * count ( $theabovexpression )

会给您涉及的节点总数。

...并且匹配的字符串是test1

我不认为仅XPath就有办法做到这一点。请记住，可能有不止一对，并且每个匹配的字符串可能都不同。但是，在XSLT中，您可以执行以下操作：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:key name="paraview" match="system[@name='paraview']" use="ancestor::word/@string" />

<xsl:template match="/dev">
    <xsl:variable name="pairs" select="word/systems/system[@name='Pstoedit'][key('paraview', ancestor::word/@string)]" />
    <result>
        <count-pairs>
            <xsl:value-of select="count($pairs)"/>
        </count-pairs>
        <match-strings>
            <xsl:for-each select="$pairs">
                <string>
                    <xsl:value-of select="ancestor::word/@string"/>
                </string>
            </xsl:for-each>
        </match-strings>
    </result>
</xsl:template>

</xsl:stylesheet>

返回：

<?xml version="1.0" encoding="UTF-8"?>
<result>
  <count-pairs>1</count-pairs>
  <match-strings>
    <string>test1</string>
  </match-strings>
</result>

编辑：

我只想要两列表中的字符串列表和总计数

尝试这种方式：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" omit-xml-declaration="yes" version="1.0" encoding="utf-8" indent="yes"/>

<xsl:key name="paraview" match="system[@name='paraview']" use="ancestor::word/@string" />

<xsl:template match="/dev">
    <xsl:variable name="pairs" select="word/systems/system[@name='Pstoedit'][key('paraview', ancestor::word/@string)]" />
    <xsl:variable name="count-pairs" select="count($pairs)" />
    <table border="1">
        <tr>
            <th>Strings</th>
            <th>Total</th>
        </tr>
        <xsl:for-each select="$pairs">
            <tr>
                <td><xsl:value-of select="ancestor::word/@string"/></td>
                <xsl:if test="position() = 1">
                    <td rowspan="{$count-pairs}">
                        <xsl:value-of select="$count-pairs"/>
                    </td>
                </xsl:if>
            </tr>
        </xsl:for-each>
    </table>
</xsl:template>

</xsl:stylesheet>

这将返回（例如，当找到两个匹配对时）：

<table border="1">
   <tr>
      <th>Strings</th>
      <th>Total</th>
   </tr>
   <tr>
      <td>stringone</td>
      <td rowspan="2">2</td>
   </tr>
   <tr>
      <td>stringtwo</td>
   </tr>
</table>

您的浏览器应将其呈现为：