如何在节点标题上加下划线或突出显示

我将为该OnDrawText事件编写一个处理程序，因为（这是此时）您将传递节点文本，将要渲染该文本的矩形以及为此渲染准备的画布，这是唯一的事件。两项任务都有更多适当的事件（例如OnBeforeCellPaint，或OnAfterItemErase用于文本背景突出显示和/OnAfterCellPaint或OnAfterItemPaint用于文本下划线），只是它们中没有一个提供特定于文本呈现的参数OnDrawText。

如果您的节点不是多行的，并且您不关心文本对齐，阅读方向或字符串缩短，那么您的任务可能与以下示例之一一样简单。

1.匹配的文字背景色

procedure TForm1.VirtualTreeDrawText(Sender: TBaseVirtualTree; TargetCanvas: TCanvas;
  Node: PVirtualNode; Column: TColumnIndex; const Text: string; const CellRect: TRect;
  var DefaultDraw: Boolean);
var
  BackMode: Integer;
begin
  // if the just rendered node's Text starts with the text written in a TEdit control
  // called Edit, then...
  if StartsText(Edit.Text, Text) then
  begin
    // store the current background mode; we need to use Windows API here because the
    // VT internally uses it (so the TCanvas object gets out of sync with the DC)
    BackMode := GetBkMode(TargetCanvas.Handle);
    // setup the color and draw the rectangle in a width of the matching text
    TargetCanvas.Brush.Color := clYellow;
    TargetCanvas.FillRect(Rect(
      CellRect.Left,
      CellRect.Top + 1,
      CellRect.Left + TargetCanvas.TextWidth(Copy(Text, 1, Length(Edit.Text))),
      CellRect.Bottom - 1)
    );
    // restore the original background mode (as it likely was modified by setting the
    // brush color)
    SetBkMode(TargetCanvas.Handle, BackMode);
  end;
end;

视觉输出示例：

2.匹配文字下划线

procedure TForm1.VirtualTreeDrawText(Sender: TBaseVirtualTree; TargetCanvas: TCanvas;
  Node: PVirtualNode; Column: TColumnIndex; const Text: string; const CellRect: TRect;
  var DefaultDraw: Boolean);
begin
  // if the just rendered node's Text starts with the text written in a TEdit control
  // called Edit, then...
  if StartsText(Edit.Text, Text) then
  begin
    TargetCanvas.Pen.Color := clRed;
    TargetCanvas.MoveTo(CellRect.Left, CellRect.Bottom - 2);
    TargetCanvas.LineTo(
      CellRect.Left + TargetCanvas.TextWidth(Copy(Text, 1, Length(Edit.Text))),
      CellRect.Bottom - 2
    );
  end;
end;

以及示例视觉输出：

在实际代码中，我建议您预先计算那些高光形状，OnDrawText以防万一只能画图，但是优化将由您自己决定；我想重点是事件本身。