将varchar数组转换为日期数组-pl sql

debugcn 发表于 Dev

保罗

我正在尝试将varchar数组转换为日期数组。当前，日期是从Java类中以字符串形式访问的，但是它必须是那里的日期。因此，我需要将varchar数组转换为date数组。我在这里只能看到有关将字符串转换为日期格式的问题，这不是我想要的。将varchar数组转换为date数组有何不同？

这是我需要程序转换的变量。

P_IN_GRID_EFFECTIVE_DATE  IN P_DVP_CONSTS.T_VCHAR10ARRAY,

亚历克斯·普尔

您可以循环一个数组，并使用其内容填充第二个数组。在这种情况下，to_date()每个条目都有一个调用。作为一个简单的演示：

create procedure convert_array(
  P_IN_GRID_EFFECTIVE_DATE IN P_DVP_CONSTS.T_VCHAR10ARRAY,
  P_OUT_GRID_EFFECTIVE_DATE OUT P_DVP_CONSTS.T_DATEARRAY
) as
begin
  P_OUT_GRID_EFFECTIVE_DATE := new P_DVP_CONSTS.T_DATEARRAY();
  P_OUT_GRID_EFFECTIVE_DATE.extend(P_IN_GRID_EFFECTIVE_DATE.count);
  for i in 1..P_IN_GRID_EFFECTIVE_DATE.count loop
    P_OUT_GRID_EFFECTIVE_DATE(i) :=
      to_date(P_IN_GRID_EFFECTIVE_DATE(i), 'YYYY-MM-DD');
      -- or whatever format your strings are using
  end loop;
end convert_array;
/

并进行快速测试：

set serveroutput on
declare
  l_strings P_DVP_CONSTS.T_VCHAR10ARRAY;
  l_dates P_DVP_CONSTS.T_DATEARRAY;
begin
  l_strings := P_DVP_CONSTS.T_VCHAR10ARRAY('2015-06-08', '2015-07-09',
    '2015-08-10');
  convert_array(l_strings, l_dates);
  dbms_output.put_line('Number of dates in array: ' || l_dates.count);
  for i in 1..l_dates.count loop
   dbms_output.put_line('Date ' || i
     || ': ' || to_char(l_dates(i), 'DD/MM/YYYY'));
  end loop;
end;
/

PL/SQL procedure successfully completed.

Number of dates in array: 3
Date 1: 08/06/2015
Date 2: 09/07/2015
Date 3: 10/08/2015

本文收集自互联网，转载请注明来源。

如有侵权，请联系[email protected] 删除。