如何在运行时拦截和替换Quartz.NET的默认日志记录？

好的，我知道了。（这次是REAL。）

澄清：当在TopShelf / Quartz.NET组合下运行.config时，抑制不存在文件时的日志记录Common.Logging。由于某些原因Appender，即使服务中的第一行代码配置了日志记录，它也始终拒绝识别运行时加载的内容。仍然是一个谜，但并不重要。（至少对我而言，最新的发现-YMMV不适合我。）

唯一被抑制的日志是跟随Common.Logging库本身的建立和删除的日志。服务本身中发生的所有事件仍将被记录下来。

我能够使用下面的代码来工作（当然，与上面链接的代码结合使用）。

如我所说，YMMV。

[服务]

Public Module Main
  Sub Main()
    Try
      BasicConfigurator.Configure(New Logger.DbAppender("ConnectionString"))
      Logger = LogManager.GetLogger(GetType(Main))

      Environment.ExitCode = HostFactory.Run(Sub(Configurator)
                                               Configurator.Service(Of Manager)(Sub(Service)
                                                                                  Service.ConstructUsing(Function(Factory) As ServiceControl
                                                                                                           Return New Manager
                                                                                                         End Function)

                                                                                  Service.WhenStarted(Function(Manager, HostControl) As Boolean
                                                                                                        Return Manager.StartService(HostControl)
                                                                                                      End Function)

                                                                                  Service.WhenStopped(Function(Manager, HostControl) As Boolean
                                                                                                        Return Manager.StopService(HostControl)
                                                                                                      End Function)
                                                                                End Sub)

                                               Configurator.SetDescription(ServiceInfo.Description)
                                               Configurator.SetServiceName(ServiceInfo.Product)
                                               Configurator.SetDisplayName(ServiceInfo.Title)
                                               Configurator.StartAutomatically()
                                               Configurator.RunAsLocalSystem()
                                             End Sub)

    Catch ex As Exception
      EventLog.WriteEntry(ServiceInfo.Product, ex.Message, EventLogEntryType.Error, 1, 1, ex.ToBytes)

    End Try
  End Sub



  Public Property Logger As ILog
End Module

[DbAppender]（使用接受连接字符串的add'l构造函数进行了更新）

Public Class DbAppender
  Inherits AdoNetAppender

  Public Sub New()
    Me.New(String.Empty)
  End Sub



  Public Sub New(ConnectionString As String)
    If Trim(ConnectionString) <> String.Empty Then
      MyBase.ConnectionString = ConnectionString
    End If

    MyBase.CommandText = Me.CommandText
    MyBase.BufferSize = 1

    Me.Parameters.ForEach(Sub(Parameter As DbParameter)
                            MyBase.AddParameter(Parameter)
                          End Sub)

    Me.ActivateOptions()
  End Sub



  Protected Overrides Function CreateConnection(ConnectionType As Type, ConnectionString As String) As IDbConnection
    Return MyBase.CreateConnection(GetType(System.Data.SqlClient.SqlConnection), MyBase.ConnectionString)
  End Function



  Private Overloads ReadOnly Property CommandText As String
    Get
      Dim _
        sColumns,
        sValues As String

      sColumns = Join(Me.Parameters.Select(Function(P As DbParameter) P.DbColumn).ToArray, ",")
      sValues = Join(Me.Parameters.Select(Function(P As DbParameter) P.ParameterName).ToArray, ",")

      Return COMMAND_TEXT.ToFormat(sColumns, sValues)
    End Get
  End Property



  Private ReadOnly Property Parameters As List(Of DbParameter)
    Get
      Parameters = New List(Of DbParameter)
      Parameters.Add(Me.Date)
      Parameters.Add(Me.Thread)
      Parameters.Add(Me.Level)
      Parameters.Add(Me.Source)
      Parameters.Add(Me.Message)
      Parameters.Add(Me.Exception)
    End Get
  End Property



  Private ReadOnly Property [Date] As DbParameter
    Get
      Return New DbParameter("Date", New DbPatternLayout(PATTERN_DATE), DbType.Date, 0)
    End Get
  End Property



  Private ReadOnly Property Thread As DbParameter
    Get
      Return New DbParameter("Thread", New DbPatternLayout(PATTERN_THREAD), DbType.String, 255)
    End Get
  End Property



  Private ReadOnly Property Level As DbParameter
    Get
      Return New DbParameter("Level", New DbPatternLayout(PATTERN_LEVEL), DbType.String, 50)
    End Get
  End Property



  Private ReadOnly Property Source As DbParameter
    Get
      Return New DbParameter("Source", New DbPatternLayout(PATTERN_SOURCE), DbType.String, 255)
    End Get
  End Property



  Private ReadOnly Property Message As DbParameter
    Get
      Return New DbParameter("Message", New DbPatternLayout(PATTERN_MESSAGE), DbType.String, 4000)
    End Get
  End Property



  Private ReadOnly Property Exception As DbParameter
    Get
      Return New DbParameter("Exception", New DbExceptionLayout)
    End Get
  End Property



  Private Const PATTERN_MESSAGE As String = "%message"
  Private Const PATTERN_THREAD As String = "%thread"
  Private Const PATTERN_SOURCE As String = "%logger.%M()"
  Private Const PATTERN_LEVEL As String = "%level"
  Private Const PATTERN_DATE As String = "%date{yyyy-MM-dd HH:mm:ss.fff}"
  Private Const COMMAND_TEXT As String = "INSERT INTO Log ({0}) VALUES ({1})"
  '======================================================================================
  ' Available patterns:
  ' http://logging.apache.org/log4net/release/sdk/log4net.Layout.PatternLayout.html
  '======================================================================================
End Class