确定VBA中图片对象的实际大小和显示大小

debugcn 发表于 Dev

python花花公子

在VBA中，我试图确定工作表上图片对象的实际大小和显示大小。由于比例因子的原因，显示的尺寸可能与实际尺寸不同。到目前为止，我已经找到了ScaleWidth和的方法ScaleHeight，但是我实际上不想修改图片对象。有任何想法吗？

玛瑞克·史蒂斯卡

不幸的是，原始的测量值似乎不是图片的公共财产。如果您不想修改原始图片，则可以仅出于缩放目的而创建所述图片的副本。

此函数接受形状（在我们的情况下为图片）并返回Single类型的数组（宽度和高度）

Private Function GetOriginalMeasurements(ByRef myShape As Excel.Shape)
    Dim shpCopy As Excel.Shape
    Dim measurements(1) As Single

    Set shpCopy = myShape.Duplicate

    ' Reset original measurements
    shpCopy.ScaleHeight 1, msoTrue

    measurements(0) = shpCopy.width
    measurements(1) = shpCopy.height

    shpCopy.Delete

    GetOriginalMeasurements = measurements
End Function

Main（）过程只是如何使用它的一个基本示例

Sub Main()
    Dim myShape As Excel.Shape
    Dim measurements() As Single
    Dim width As Single
    Dim height As Single

    Set myShape = ActiveWorkbook.ActiveSheet.Shapes(1)
    measurements = GetOriginalMeasurements(myShape)

    width = measurements(0)
    height = measurements(1)

    Debug.Print width
    Debug.Print height
End Sub

在我的计算机上，形状的复制和删除是即时的，但是如果您看到一些闪烁，则可能希望在该功能中关闭屏幕更新。

本文收集自互联网，转载请注明来源。

如有侵权，请联系[email protected] 删除。