用于为相应的Windows版本安装Service Pack的脚本

我不知道如何将这些命令放在一起

我知道我可以做：

   wmic os get Caption

获取窗口版本和：

   wmic os get ServicePackMajorVersion

获取服务包。

您确实可以wmic用来检索这些值。但是，为了以后在批处理文件中（例如在if表达式中）使用它们，您需要将值存储在环境变量中。

这是如何执行此操作的示例：

@echo off
setlocal
setlocal enabledelayedexpansion
set _os=
set _sp=
rem use findstr to strip blank lines from wmic output
for /f "usebackq skip=1 tokens=3" %%i in (`wmic os get caption ^| findstr /r /v "^$"`) do (
  set "_os=%%i"
  )
for /f "usebackq skip=1 tokens=*" %%i in (`wmic os get ServicePackMajorVersion ^| findstr /r /v "^$"`) do (
  set "_sp=%%i"
  )
echo Operating System: %_os%
echo Service Pack Major Version: %_sp%
endlocal

现在，我们将操作系统存储在中%_os，将Service Pack主要版本存储在中%_sp%。

笔记：

1. 我们不能在字符串比较中使用正则表达式，不支持它们。

2. 该for命令仅检索操作系统的第3部分（令牌）。这将适用于台式机版本（如果要将Server 2008与其他版本区分开，则需要找到其他解决方案）。

3. _os将被设置为以下值中的一个Server，Vista，7，8，或8.1，所以正则表达式不再需要。

接下来，我们需要更改if语句，以便它们使用存储的变量并正确执行字符串比较。

if /i {Caption}=={Microsoft Windows Server 2008 *} goto :WinS

变成：

if /i "%_os%" == "Server" goto :WinS

等等。

放在一起，使用以下批处理文件：

@echo off
setlocal
setlocal enabledelayedexpansion
set _os=
set _sp=
rem use findstr to strip blank lines from wmic output
for /f "usebackq skip=1 tokens=3" %%i in (`wmic os get caption ^| findstr /r /v "^$"`) do (
  set "_os=%%i"
  )
for /f "usebackq skip=1 tokens=1" %%i in (`wmic os get ServicePackMajorVersion ^| findstr /r /v "^$"`) do (
  set "_sp=%%i"
  )
echo Operating System: %_os%
echo Service Pack Major Version: %_sp%

if /i "%_os%" == "7" echo Win7

if /i "%_os%" == "Server" goto :WinS
if /i "%_os%" == "Vista"  goto :WinV
if /i "%_os%" == "7"      goto :Win7
if /i "%_os%" == "8"      goto :Win8
if /i "%_os%" == "8.1"    goto :Win8.1
echo Windows Version not Supported! 
pause 
goto :eof

:WinS
if /i "%_sp%" == "0" start /wait %~dp0\servicepackSV1.exe
if /i "%_sp%" == "1" start /wait %~dp0\servicepackSV2.exe 
if /i "%_sp%" == "2" goto :GoodtoGo 
echo Service Pack Installed!!
goto :eof

:WinV
if /i "%_sp%" == "0" start /wait %~dp0\servicepackSV1.exe
if /i "%_sp%" == "1" start /wait %~dp0\servicepackSV2.exe 
if /i "%_sp%" == "2" goto :GoodtoGo 
echo Service Pack Installed!!
goto :eof

:Win7
if /i "%_sp%" == "0" start /wait %~dp0\servicepack7.exe 
if /i "%_sp%" == "1" goto :GoodtoGo 
echo Service Pack Installed!!
goto :eof

:Win8
echo No service pack needed!
goto :eof

:Win8.1
wmic qfe get hotfixid | find "KB2919355"
if %errorlevel%==0 goto :GoodtoGo
start /wait %~dp0\win8.exe
goto :eof

:GoodtoGo
echo The Latest ServicePack is already installed!
goto :eof

endlocal

笔记：

• 没有经过完全测试，因为我没有所有的OS和SP组合都可以对其进行测试。
• 一些不完整的goto陈述也得到了修复。

那32位和64位呢？如何确定我是哪个系统？

使用以下批处理文件（GetBits.cmd）：

@echo off
setlocal enabledelayedexpansion
for /f "usebackq skip=1 tokens=*" %%i in (`wmic OS get OSArchitecture ^| findstr /r /v "^$"`) do (
  set "_bits=%%i"
  )
echo %_bits%
endlocal

输出示例：

F:\test>GetBits
64-bit

F:\test>

进一步阅读

• Windows CMD命令行的AZ索引-Windows cmd行相关的所有内容的出色参考。
• findstr-搜索文件中的字符串。
• / f-针对另一个命令的结果循环命令。
• if-有条件地执行命令。
• wmic -Windows管理规范命令。