使用Delphi查找特殊驱动器

debugcn 发表于 Dev

卡纳迪亚人

我试图在Delphi 2007中编写一个小程序，以便在将便携式USB驱动器插入Windows 7计算机时访问文件。但是，该驱动器未显示为标准驱动器号。它显示在Windows资源管理器中的“便携式设备”下。我编写了以下代码来枚举“计算机”下的所有项目：

Procedure TfrmMain.ComputerChanged(Var Msg: TMessage);
Var
  Enum: IEnumIDList;
  Fetched: Longword;
  Item: PItemIDList;
  Path: String;
  Computer: IShellFolder;
  StrRet: TSTRRET;
Begin
  Status('Computer changed...  Checking folders.');
  fDesktop.BindToObject(fCompPidl, Nil, IID_IShellFolder, Computer);
  If Assigned(Computer) And
     (Computer.EnumObjects(Self.Handle, SHCONTF_FOLDERS, Enum) = NOERROR) Then
  Begin
    While (Enum.Next(1, Item, Fetched) = NOERROR) Do
    Begin
      FillChar(StrRet, SizeOf(StrRet), #0);
      Computer.GetDisplayNameOf(Item, SHGDN_FORADDRESSBAR or SHGDN_NORMAL, StrRet);
      Path := StrRetToStr(StrRet, Item);
      Status(Path);
    End;
  End;
End;

（注意：“状态”过程仅向TMemo输出一条消息。）

每当Windows Shell子系统通知我的应用程序有更改时，就会调用此方法。它枚举了所有本地驱动器和网络驱动器，但没有其他枚举（也缺少iCloud Photos驱动器）。

有谁知道我如何访问这些虚拟驱动器上的文件？

佐伊·彼得森（ZoëPeterson）

您很有可能没有正确初始化COM。如果您不调用CoInitializeEx或以错误的值调用它，则您的代码将按原样工作，但是便携式设备驱动程序需要单元线程才能工作。

根据您的代码，这是一个示例应用程序，可以正常运行并显示便携式设备。如果您注释掉CoInitializeEx/CoUninitialize调用或传递，COINIT_MULTITHREADED它仍然可以工作，但是只显示驱动器。

program ListMyComputer;

{$APPTYPE CONSOLE}

uses
  ComObj, ShlObj, ShellApi, ShLwApi, ActiveX, Windows, SysUtils;

var
  Enum: IEnumIDList;
  Fetched: Longword;
  CompPidl, Item: PItemIDList;
  Path: PWideChar;
  Desktop, Computer: IShellFolder;
  StrRet: TSTRRET;
begin
  CoInitializeEx(nil, COINIT_APARTMENTTHREADED);
  try
    WriteLn('Computer changed...  Checking folders.');
    SHGetDesktopFolder(Desktop);
    SHGetFolderLocation(0, CSIDL_DRIVES, 0, 0, CompPidl);
    Desktop.BindToObject(CompPidl, Nil, IID_IShellFolder, Computer);
    CoTaskMemFree(CompPidl);
    If Assigned(Computer) And
       (Computer.EnumObjects(0, SHCONTF_FOLDERS, Enum) = NOERROR) Then
    Begin
      While (Enum.Next(1, Item, Fetched) = NOERROR) Do
      Begin
        FillChar(StrRet, SizeOf(StrRet), #0);
        Computer.GetDisplayNameOf(Item, SHGDN_FORADDRESSBAR or SHGDN_NORMAL, StrRet);
        StrRetToStr(@StrRet, Item, Path);
        WriteLn(Path);
        CoTaskMemFree(Path);
      End;
    End;
    WriteLn('Enumeration complete');
    ReadLn;
  finally
    CoUninitialize
  end;
end.

本文收集自互联网，转载请注明来源。

如有侵权，请联系[email protected] 删除。

编辑于2021-06-7

我来说两句

0条评论

登录后参与评论

来自分类Dev

Related 相关文章

文章