为什么以下使用IOmniThreadPool的代码会导致访问冲突？

debugcn 发表于 Dev

提姆

在我们的Delphi XE4应用程序中，我们使用MaxExecuting = 4的OmniThreadPool来提高特定计算的效率。不幸的是，我们遇到断断续续的访问冲突（例如，请参阅以下MadExcept错误报告http://ec2-72-44-42-247.compute-1.amazonaws.com/BugReport.txt）。我能够构造以下示例来说明问题。运行以下控制台应用程序后，通常在一分钟左右的时间内发生System.SyncObjs.TCriticalSection.Acquire中的访问冲突。有人可以告诉我我在以下代码中做错了什么吗，还是告诉我另一种实现预期结果的方法？

program OmniPoolCrashTest;

{$APPTYPE CONSOLE}

uses
  Winapi.Windows, System.SysUtils,
  DSiWin32, GpLists,
  OtlSync, OtlThreadPool, OtlTaskControl, OtlComm, OtlTask;

const
  cTimeToWaitForException = 10 * 60 * 1000;  // program exits if no exception after 10 minutes
  MSG_CALLEE_FINISHED = 113; // our custom Omni message ID
  cMaxAllowedParallelCallees = 4; // enforced via thread pool
  cCalleeDuration = 10; // 10 miliseconds
  cCallerRepetitionInterval = 200; // 200 milliseconds
  cDefaultNumberOfCallers = 10; // 10 callers each issuing 1 call every 200 milliseconds

var
  gv_OmniThreadPool : IOmniThreadPool;

procedure OmniTaskProcedure_Callee(const task: IOmniTask);
begin
  Sleep(cCalleeDuration);
  task.Comm.Send(MSG_CALLEE_FINISHED);
end;

procedure PerformThreadPoolTest();
var
  OmniTaskControl : IOmniTaskControl;
begin
  OmniTaskControl := CreateTask(OmniTaskProcedure_Callee).Schedule(gv_OmniThreadPool);
  WaitForSingleObject(OmniTaskControl.Comm.NewMessageEvent, INFINITE);
end;

procedure OmniTaskProcedure_Caller(const task: IOmniTask);
begin
  while not task.Terminated do begin
    PerformThreadPoolTest();
    Sleep(cCallerRepetitionInterval);
  end;
end;

var
  CallerTasks : TGpInterfaceList<IOmniTaskControl>;
  i : integer;
begin
  gv_OmniThreadPool := CreateThreadPool('CalleeThreadPool');
  gv_OmniThreadPool.MaxExecuting := cMaxAllowedParallelCallees;
  CallerTasks := TGpInterfaceList<IOmniTaskControl>.Create();
  for i := 1 to StrToIntDef(ParamStr(1), cDefaultNumberOfCallers) do begin
    CallerTasks.Add( CreateTask(OmniTaskProcedure_Caller).Run() );
  end;
  Sleep(cTimeToWaitForException);
  for i := 0 to CallerTasks.Count-1 do begin
    CallerTasks[i].Terminate();
  end;
  CallerTasks.Free();
end.

加布

您在这里有一个难以找到的示例Task Controller需要所有者问题。发生的情况是，任务控制器有时会在任务本身之前被破坏，从而导致任务访问包含随机数据的内存。

问题场景如下所示（[T]标记任务，[C]标记任务控制器）：

[T]发送消息
[C]收到消息并退出
[C]被摧毁
创建了新任务[T1]和控制器[C1]
[T]试图退出；在此期间，它访问由[C]管理但随后被属于[C1]或[T1]的数据破坏并覆盖的共享存储区

在Graymatter的解决方法中，OnTerminated为OmniThreadLibrary内部的任务创建一个隐式所有者，以“解决”问题。

等待任务完成的正确方法是调用taskControler.WaitFor。

procedure OmniTaskProcedure_Callee(const task: IOmniTask);
begin
  Sleep(cCalleeDuration);
end;

procedure PerformThreadPoolTest();
var
  OmniTaskControl : IOmniTaskControl;
begin
  OmniTaskControl := CreateTask(OmniTaskProcedure_Callee).Schedule(gv_OmniThreadPool);
  OmniTaskControl.WaitFor(INFINITE);
end;

我将研究用引用计数解决方案替换共享内存记录，以防止此类问题发生（或至少使它们更易于发现）。

本文收集自互联网，转载请注明来源。

如有侵权，请联系[email protected] 删除。

编辑于2021-06-7

我来说两句

0条评论

登录后参与评论

来自分类Dev

Related 相关文章

文章