仅当单元格值更改时，如何执行指令？

debugcn 发表于 Dev

里卡多·马丁（Ricardo Martin）

我有一个ByVal代码来清除表内特定范围的内容，它可以工作。但是，如果范围值（内容）发生变化，则需要为执行指令添加条件，而不是仅将光标放在其上。

另外，有人知道如何在VBA中引用表列吗？现在，我使用的估计范围是“ C1：C999”，但我想使用他的名字“ A_ [OPERATION]”。

这是代码：

Private Sub Worksheet_SelectionChange(ByVal Target As Range)

   If Not Application.Intersect(Range("C1:C999"), Range(Target.Address)) Is Nothing Then
    
       Range(Selection, Selection.End(xlToRight)).ClearContents

   End If

End Sub

VBasic2008

工作表变更

调整表名称（tName）和标题（列）名称（hName）。
我已经对其进行了调整，以清除列后单元格中的内容。
如果您确实还需要清除该列的内容，请替换cel.Offset(, 1)为cel。
在表格中，如果手动或通过VBA更改了列中的值，则当前设置将自动清除指定列右侧的所有单元格的内容。如果该列包含公式，则将无法使用。还支持非连续删除。

编码

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
    
    Const ProcName As String = "Worksheet_Change"
    On Error GoTo clearError
    
    Const tName As String = "A_"
    Const hName As String = "OPERATION"
    
    Dim rng As Range
    Set rng = Range(tName & "[" & hName & "]")
    Set rng = Intersect(rng, Target)
    If rng Is Nothing Then GoTo ProcExit
    
    Application.EnableEvents = False
    
    With ListObjects(tName).HeaderRowRange
        Dim LastColumn As Long
        LastColumn = .Columns(.Columns.Count).Column
    End With
    Dim cel As Range
    For Each rng In rng.Areas
        For Each cel In rng.Cells
            With cel.Offset(, 1)
                .Resize(, LastColumn - .Column + 1).ClearContents
            End With
        Next cel
    Next rng

CleanExit:
    Application.EnableEvents = True
    GoTo ProcExit

clearError:
    Debug.Print "'" & ProcName & "': " & vbLf _
              & "    " & "Run-time error '" & Err.Number & "':" & vbLf _
              & "        " & Err.Description
    On Error GoTo 0
    GoTo CleanExit

ProcExit:

End Sub